mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-08 14:03:29 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
51 lines
1.2 KiB
Nix
51 lines
1.2 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, openssl, pkg-config, libpcap }:
|
|
|
|
buildGoModule rec {
|
|
pname = "mongo-tools";
|
|
version = "100.10.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "mongodb";
|
|
repo = "mongo-tools";
|
|
rev = version;
|
|
sha256 = "sha256-9DUfPD6wrv65PLVtxAF21BZ/joWFVFk+cItt9m/1Nx8=";
|
|
};
|
|
|
|
vendorHash = null;
|
|
|
|
nativeBuildInputs = [ pkg-config ];
|
|
buildInputs = [ openssl libpcap ];
|
|
|
|
# Mongodb incorrectly names all of their binaries main
|
|
# Let's work around this with our own installer
|
|
buildPhase =
|
|
let
|
|
tools = [
|
|
"bsondump"
|
|
"mongodump"
|
|
"mongoexport"
|
|
"mongofiles"
|
|
"mongoimport"
|
|
"mongorestore"
|
|
"mongostat"
|
|
"mongotop"
|
|
]; in
|
|
''
|
|
# move vendored codes so nixpkgs go builder could find it
|
|
runHook preBuild
|
|
|
|
${lib.concatMapStrings (t: ''
|
|
go build -o "$out/bin/${t}" -tags ssl -ldflags "-s -w" ./${t}/main
|
|
'') tools}
|
|
|
|
runHook postBuild
|
|
'';
|
|
|
|
meta = {
|
|
homepage = "https://github.com/mongodb/mongo-tools";
|
|
description = "Tools for the MongoDB";
|
|
license = lib.licenses.asl20;
|
|
maintainers = with lib.maintainers; [ bryanasdev000 ];
|
|
};
|
|
}
|