mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-26 17:03:01 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
78 lines
2.2 KiB
Nix
78 lines
2.2 KiB
Nix
{ lib, stdenv, fetchurl, unzip, makeWrapper, flex, bison, ncurses, buddy, tecla
|
|
, libsigsegv, gmpxx, cln, yices
|
|
# passthru.tests
|
|
, tamarin-prover
|
|
}:
|
|
|
|
let
|
|
version = "3.4";
|
|
in
|
|
|
|
stdenv.mkDerivation {
|
|
pname = "maude";
|
|
inherit version;
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/maude-lang/Maude/archive/refs/tags/Maude${version}.tar.gz";
|
|
sha256 = "IXWEWAmh388NpNSt9wnOpLkzhZ09N+AStO2wn5dRT8o=";
|
|
};
|
|
|
|
nativeBuildInputs = [ flex bison unzip makeWrapper ];
|
|
buildInputs = [
|
|
ncurses buddy tecla gmpxx libsigsegv cln yices
|
|
];
|
|
|
|
hardeningDisable = [ "stackprotector" ] ++
|
|
lib.optionals stdenv.hostPlatform.isi686 [ "pic" "fortify" ];
|
|
|
|
# Fix for glibc-2.34, see
|
|
# https://gitweb.gentoo.org/repo/gentoo.git/commit/dev-lang/maude/maude-3.1-r1.ebuild?id=f021cc6cfa1e35eb9c59955830f1fd89bfcb26b4
|
|
configureFlags = [ "--without-libsigsegv" ];
|
|
|
|
# Certain tests (in particular, Misc/fileTest) expect us to build in a subdirectory
|
|
# We'll use the directory Opt/ as suggested in INSTALL
|
|
preConfigure = ''
|
|
mkdir Opt; cd Opt
|
|
configureFlagsArray=(
|
|
--datadir="$out/share/maude"
|
|
TECLA_LIBS="-ltecla -lncursesw"
|
|
LIBS="-lcln"
|
|
CFLAGS="-O3" CXXFLAGS="-O3"
|
|
)
|
|
'';
|
|
configureScript = "../configure";
|
|
|
|
doCheck = true;
|
|
|
|
postInstall = ''
|
|
for n in "$out/bin/"*; do wrapProgram "$n" --suffix MAUDE_LIB ':' "$out/share/maude"; done
|
|
'';
|
|
|
|
passthru.tests = {
|
|
# tamarin-prover only supports specific versions of maude explicitly
|
|
inherit tamarin-prover;
|
|
};
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = {
|
|
homepage = "http://maude.cs.illinois.edu/";
|
|
description = "High-level specification language";
|
|
mainProgram = "maude";
|
|
license = lib.licenses.gpl2Plus;
|
|
|
|
longDescription = ''
|
|
Maude is a high-performance reflective language and system
|
|
supporting both equational and rewriting logic specification and
|
|
programming for a wide range of applications. Maude has been
|
|
influenced in important ways by the OBJ3 language, which can be
|
|
regarded as an equational logic sublanguage. Besides supporting
|
|
equational specification and programming, Maude also supports
|
|
rewriting logic computation.
|
|
'';
|
|
|
|
platforms = lib.platforms.unix;
|
|
maintainers = [ lib.maintainers.peti ];
|
|
};
|
|
}
|