mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-07 21:43:32 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
141 lines
3.0 KiB
Nix
141 lines
3.0 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitLab,
|
|
fetchpatch,
|
|
cmake,
|
|
pkg-config,
|
|
wrapQtAppsHook,
|
|
SDL2,
|
|
CoreMedia,
|
|
VideoToolbox,
|
|
VideoDecodeAcceleration,
|
|
boost,
|
|
bullet,
|
|
# Please unpin this on the next OpenMW release.
|
|
ffmpeg_6,
|
|
libXt,
|
|
luajit,
|
|
lz4,
|
|
mygui,
|
|
openal,
|
|
openscenegraph,
|
|
recastnavigation,
|
|
unshield,
|
|
yaml-cpp,
|
|
}:
|
|
|
|
let
|
|
GL = "GLVND"; # or "LEGACY";
|
|
|
|
osg' = (openscenegraph.override { colladaSupport = true; }).overrideDerivation (old: {
|
|
patches = [
|
|
(fetchpatch {
|
|
# Darwin: Without this patch, OSG won't build osgdb_png.so, which is required by OpenMW.
|
|
name = "darwin-osg-plugins-fix.patch";
|
|
url = "https://gitlab.com/OpenMW/openmw-dep/-/raw/0abe3c9c3858211028d881d7706813d606335f72/macos/osg.patch";
|
|
sha256 = "sha256-/CLRZofZHot8juH78VG1/qhTHPhy5DoPMN+oH8hC58U=";
|
|
})
|
|
];
|
|
cmakeFlags =
|
|
(old.cmakeFlags or [ ])
|
|
++ [
|
|
"-Wno-dev"
|
|
"-DOpenGL_GL_PREFERENCE=${GL}"
|
|
"-DBUILD_OSG_PLUGINS_BY_DEFAULT=0"
|
|
"-DBUILD_OSG_DEPRECATED_SERIALIZERS=0"
|
|
]
|
|
++ (map (e: "-DBUILD_OSG_PLUGIN_${e}=1") [
|
|
"BMP"
|
|
"DAE"
|
|
"DDS"
|
|
"FREETYPE"
|
|
"JPEG"
|
|
"OSG"
|
|
"PNG"
|
|
"TGA"
|
|
]);
|
|
});
|
|
|
|
bullet' = bullet.overrideDerivation (old: {
|
|
cmakeFlags = (old.cmakeFlags or [ ]) ++ [
|
|
"-Wno-dev"
|
|
"-DOpenGL_GL_PREFERENCE=${GL}"
|
|
"-DUSE_DOUBLE_PRECISION=ON"
|
|
"-DBULLET2_MULTITHREADING=ON"
|
|
];
|
|
});
|
|
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = "openmw";
|
|
version = "0.48.0";
|
|
|
|
src = fetchFromGitLab {
|
|
owner = "OpenMW";
|
|
repo = "openmw";
|
|
rev = "${pname}-${version}";
|
|
hash = "sha256-zkjVt3GfQZsFXl2Ht3lCuQtDMYQWxhdFO4aGSb3rsyo=";
|
|
};
|
|
|
|
postPatch =
|
|
''
|
|
sed '1i#include <memory>' -i components/myguiplatform/myguidatamanager.cpp # gcc12
|
|
''
|
|
+ lib.optionalString stdenv.hostPlatform.isDarwin ''
|
|
# Don't fix Darwin app bundle
|
|
sed -i '/fixup_bundle/d' CMakeLists.txt
|
|
'';
|
|
|
|
nativeBuildInputs = [
|
|
cmake
|
|
pkg-config
|
|
wrapQtAppsHook
|
|
];
|
|
|
|
# If not set, OSG plugin .so files become shell scripts on Darwin.
|
|
dontWrapQtApps = stdenv.hostPlatform.isDarwin;
|
|
|
|
buildInputs =
|
|
[
|
|
SDL2
|
|
boost
|
|
bullet'
|
|
ffmpeg_6
|
|
libXt
|
|
luajit
|
|
lz4
|
|
mygui
|
|
openal
|
|
osg'
|
|
recastnavigation
|
|
unshield
|
|
yaml-cpp
|
|
]
|
|
++ lib.optionals stdenv.hostPlatform.isDarwin [
|
|
CoreMedia
|
|
VideoDecodeAcceleration
|
|
VideoToolbox
|
|
];
|
|
|
|
cmakeFlags =
|
|
[
|
|
"-DOpenGL_GL_PREFERENCE=${GL}"
|
|
"-DOPENMW_USE_SYSTEM_RECASTNAVIGATION=1"
|
|
]
|
|
++ lib.optionals stdenv.hostPlatform.isDarwin [
|
|
"-DOPENMW_OSX_DEPLOYMENT=ON"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "Unofficial open source engine reimplementation of the game Morrowind";
|
|
homepage = "https://openmw.org";
|
|
license = licenses.gpl3Plus;
|
|
maintainers = with maintainers; [
|
|
abbradar
|
|
marius851000
|
|
];
|
|
platforms = platforms.linux ++ platforms.darwin;
|
|
};
|
|
}
|