mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-02-20 19:16:11 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
70 lines
2.5 KiB
Nix
70 lines
2.5 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, installShellFiles }:
|
|
|
|
buildGoModule rec {
|
|
pname = "crowdsec";
|
|
version = "1.6.3";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "crowdsecurity";
|
|
repo = pname;
|
|
rev = "refs/tags/v${version}";
|
|
hash = "sha256-JN2siYUUFPSz+SyQwkX6DZ9k82SGHEQ1QHBEIfEV4EM=";
|
|
};
|
|
|
|
vendorHash = "sha256-fl5LkRz69QOq4aPyAhMFxw1FWozLzofDBUGvRptuyZY=";
|
|
|
|
nativeBuildInputs = [ installShellFiles ];
|
|
|
|
subPackages = [
|
|
"cmd/crowdsec"
|
|
"cmd/crowdsec-cli"
|
|
];
|
|
|
|
ldflags = [
|
|
"-s"
|
|
"-w"
|
|
"-X github.com/crowdsecurity/go-cs-lib/version.Version=v${version}"
|
|
"-X github.com/crowdsecurity/go-cs-lib/version.BuildDate=1970-01-01_00:00:00"
|
|
"-X github.com/crowdsecurity/go-cs-lib/version.Tag=${src.rev}"
|
|
"-X github.com/crowdsecurity/crowdsec/pkg/cwversion.Codename=alphaga"
|
|
"-X github.com/crowdsecurity/crowdsec/pkg/csconfig.defaultConfigDir=/etc/crowdsec"
|
|
"-X github.com/crowdsecurity/crowdsec/pkg/csconfig.defaultDataDir=/var/lib/crowdsec/data"
|
|
];
|
|
|
|
postBuild = "mv $GOPATH/bin/{crowdsec-cli,cscli}";
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/share/crowdsec
|
|
cp -r ./config $out/share/crowdsec/
|
|
|
|
installShellCompletion --cmd cscli \
|
|
--bash <($out/bin/cscli completion bash) \
|
|
--fish <($out/bin/cscli completion fish) \
|
|
--zsh <($out/bin/cscli completion zsh)
|
|
'';
|
|
|
|
# It's important that the version is correctly set as it also determines feature capabilities
|
|
checkPhase = ''
|
|
$GOPATH/bin/cscli version 2>&1 | grep -q "version: v${version}"
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://crowdsec.net/";
|
|
changelog = "https://github.com/crowdsecurity/crowdsec/releases/tag/v${version}";
|
|
description = "CrowdSec is a free, open-source and collaborative IPS";
|
|
longDescription = ''
|
|
CrowdSec is a free, modern & collaborative behavior detection engine,
|
|
coupled with a global IP reputation network. It stacks on fail2ban's
|
|
philosophy but is IPV6 compatible and 60x faster (Go vs Python), uses Grok
|
|
patterns to parse logs and YAML scenario to identify behaviors. CrowdSec
|
|
is engineered for modern Cloud/Containers/VM based infrastructures (by
|
|
decoupling detection and remediation). Once detected you can remedy
|
|
threats with various bouncers (firewall block, nginx http 403, Captchas,
|
|
etc.) while the aggressive IP can be sent to CrowdSec for curation before
|
|
being shared among all users to further improve everyone's security.
|
|
'';
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ jk urandom ];
|
|
};
|
|
}
|