mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-15 02:03:01 +00:00
209 lines
7.8 KiB
Nix
209 lines
7.8 KiB
Nix
{ stdenv, targetPackages
|
|
, buildPlatform, hostPlatform, targetPlatform
|
|
|
|
# build-tools
|
|
, bootPkgs, alex, happy, hscolour
|
|
, autoconf, automake, coreutils, fetchgit, perl, python3, m4
|
|
|
|
, libiconv ? null, ncurses
|
|
|
|
, useLLVM ? !targetPlatform.isx86 || (targetPlatform.isMusl && hostPlatform != targetPlatform)
|
|
, # LLVM is conceptually a run-time-only depedendency, but for
|
|
# non-x86, we need LLVM to bootstrap later stages, so it becomes a
|
|
# build-time dependency too.
|
|
buildLlvmPackages, llvmPackages
|
|
|
|
, # If enabled, GHC will be built with the GPL-free but slower integer-simple
|
|
# library instead of the faster but GPLed integer-gmp library.
|
|
enableIntegerSimple ? !(gmp.meta.available or false), gmp
|
|
|
|
, # If enabled, use -fPIC when compiling static libs.
|
|
enableRelocatedStaticLibs ? targetPlatform != hostPlatform
|
|
|
|
, # Whether to build dynamic libs for the standard library (on the target
|
|
# platform). Static libs are always built.
|
|
enableShared ? !targetPlatform.isWindows && !targetPlatform.useAndroidPrebuilt
|
|
|
|
, # Whetherto build terminfo.
|
|
enableTerminfo ? !targetPlatform.isWindows
|
|
|
|
, version ? "8.5.20180118"
|
|
, # What flavour to build. An empty string indicates no
|
|
# specific flavour and falls back to ghc default values.
|
|
ghcFlavour ? stdenv.lib.optionalString (targetPlatform != hostPlatform) "perf-cross"
|
|
}:
|
|
|
|
let
|
|
inherit (bootPkgs) ghc;
|
|
|
|
# TODO(@Ericson2314) Make unconditional
|
|
targetPrefix = stdenv.lib.optionalString
|
|
(targetPlatform != hostPlatform)
|
|
"${targetPlatform.config}-";
|
|
|
|
buildMK = ''
|
|
BuildFlavour = ${ghcFlavour}
|
|
ifneq \"\$(BuildFlavour)\" \"\"
|
|
include mk/flavours/\$(BuildFlavour).mk
|
|
endif
|
|
DYNAMIC_GHC_PROGRAMS = ${if enableShared then "YES" else "NO"}
|
|
'' + stdenv.lib.optionalString enableIntegerSimple ''
|
|
INTEGER_LIBRARY = integer-simple
|
|
'' + stdenv.lib.optionalString (targetPlatform != hostPlatform) ''
|
|
Stage1Only = ${if targetPlatform.system == hostPlatform.system then "NO" else "YES"}
|
|
CrossCompilePrefix = ${targetPrefix}
|
|
HADDOCK_DOCS = NO
|
|
BUILD_SPHINX_HTML = NO
|
|
BUILD_SPHINX_PDF = NO
|
|
'' + stdenv.lib.optionalString enableRelocatedStaticLibs ''
|
|
GhcLibHcOpts += -fPIC
|
|
GhcRtsHcOpts += -fPIC
|
|
'' + stdenv.lib.optionalString targetPlatform.useAndroidPrebuilt ''
|
|
EXTRA_CC_OPTS += -std=gnu99
|
|
'';
|
|
|
|
# Splicer will pull out correct variations
|
|
libDeps = platform: stdenv.lib.optional enableTerminfo [ ncurses ]
|
|
++ stdenv.lib.optional (!enableIntegerSimple) gmp
|
|
++ stdenv.lib.optional (platform.libc != "glibc" && !targetPlatform.isWindows) libiconv;
|
|
|
|
toolsForTarget =
|
|
if hostPlatform == buildPlatform then
|
|
[ targetPackages.stdenv.cc ] ++ stdenv.lib.optional useLLVM llvmPackages.llvm
|
|
else assert targetPlatform == hostPlatform; # build != host == target
|
|
[ stdenv.cc ] ++ stdenv.lib.optional useLLVM buildLlvmPackages.llvm;
|
|
|
|
targetCC = builtins.head toolsForTarget;
|
|
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
inherit version;
|
|
inherit (src) rev;
|
|
name = "${targetPrefix}ghc-${version}";
|
|
|
|
src = fetchgit {
|
|
url = "git://git.haskell.org/ghc.git";
|
|
rev = "e1d4140be4d2a1508015093b69e1ef53516e1eb6";
|
|
sha256 = "1gdcr10dd968d40qgljdwx9vfkva3yrvjm9a4nis7whaaac3ag58";
|
|
};
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
outputs = [ "out" "doc" ];
|
|
|
|
postPatch = "patchShebangs .";
|
|
|
|
# GHC is a bit confused on its cross terminology.
|
|
preConfigure = ''
|
|
for env in $(env | grep '^TARGET_' | sed -E 's|\+?=.*||'); do
|
|
export "''${env#TARGET_}=''${!env}"
|
|
done
|
|
# GHC is a bit confused on its cross terminology, as these would normally be
|
|
# the *host* tools.
|
|
export CC="${targetCC}/bin/${targetCC.targetPrefix}cc"
|
|
export CXX="${targetCC}/bin/${targetCC.targetPrefix}cxx"
|
|
# Use gold to work around https://sourceware.org/bugzilla/show_bug.cgi?id=16177
|
|
export LD="${targetCC.bintools}/bin/${targetCC.bintools.targetPrefix}ld${stdenv.lib.optionalString targetPlatform.isAarch32 ".gold"}"
|
|
export AS="${targetCC.bintools.bintools}/bin/${targetCC.bintools.targetPrefix}as"
|
|
export AR="${targetCC.bintools.bintools}/bin/${targetCC.bintools.targetPrefix}ar"
|
|
export NM="${targetCC.bintools.bintools}/bin/${targetCC.bintools.targetPrefix}nm"
|
|
export RANLIB="${targetCC.bintools.bintools}/bin/${targetCC.bintools.targetPrefix}ranlib"
|
|
export READELF="${targetCC.bintools.bintools}/bin/${targetCC.bintools.targetPrefix}readelf"
|
|
export STRIP="${targetCC.bintools.bintools}/bin/${targetCC.bintools.targetPrefix}strip"
|
|
|
|
echo -n "${buildMK}" > mk/build.mk
|
|
echo ${version} >VERSION
|
|
echo ${src.rev} >GIT_COMMIT_ID
|
|
./boot
|
|
sed -i -e 's|-isysroot /Developer/SDKs/MacOSX10.5.sdk||' configure
|
|
'' + stdenv.lib.optionalString (!stdenv.isDarwin) ''
|
|
export NIX_LDFLAGS+=" -rpath $out/lib/ghc-${version}"
|
|
'' + stdenv.lib.optionalString stdenv.isDarwin ''
|
|
export NIX_LDFLAGS+=" -no_dtrace_dof"
|
|
'';
|
|
|
|
# TODO(@Ericson2314): Always pass "--target" and always prefix.
|
|
configurePlatforms = [ "build" "host" ]
|
|
++ stdenv.lib.optional (targetPlatform != hostPlatform) "target";
|
|
# `--with` flags for libraries needed for RTS linker
|
|
configureFlags = [
|
|
"--datadir=$doc/share/doc/ghc"
|
|
"--with-curses-includes=${ncurses.dev}/include" "--with-curses-libraries=${ncurses.out}/lib"
|
|
] ++ stdenv.lib.optional (targetPlatform == hostPlatform && ! enableIntegerSimple) [
|
|
"--with-gmp-includes=${gmp.dev}/include" "--with-gmp-libraries=${gmp.out}/lib"
|
|
] ++ stdenv.lib.optional (targetPlatform == hostPlatform && hostPlatform.libc != "glibc" && !targetPlatform.isWindows) [
|
|
"--with-iconv-includes=${libiconv}/include" "--with-iconv-libraries=${libiconv}/lib"
|
|
] ++ stdenv.lib.optionals (targetPlatform != hostPlatform) [
|
|
"--enable-bootstrap-with-devel-snapshot"
|
|
] ++ stdenv.lib.optionals (targetPlatform.isAarch32) [
|
|
"CFLAGS=-fuse-ld=gold"
|
|
"CONF_GCC_LINKER_OPTS_STAGE1=-fuse-ld=gold"
|
|
"CONF_GCC_LINKER_OPTS_STAGE2=-fuse-ld=gold"
|
|
] ++ stdenv.lib.optionals (targetPlatform.isDarwin && targetPlatform.isAarch64) [
|
|
# fix for iOS: https://www.reddit.com/r/haskell/comments/4ttdz1/building_an_osxi386_to_iosarm64_cross_compiler/d5qvd67/
|
|
"--disable-large-address-space"
|
|
];
|
|
|
|
# Make sure we never relax`$PATH` and hooks support for compatability.
|
|
strictDeps = true;
|
|
|
|
nativeBuildInputs = [
|
|
perl autoconf automake m4 python3
|
|
ghc alex happy hscolour
|
|
];
|
|
|
|
# For building runtime libs
|
|
depsBuildTarget = toolsForTarget;
|
|
|
|
buildInputs = libDeps hostPlatform;
|
|
|
|
propagatedBuildInputs = [ targetPackages.stdenv.cc ]
|
|
++ stdenv.lib.optional useLLVM llvmPackages.llvm;
|
|
|
|
depsTargetTarget = map stdenv.lib.getDev (libDeps targetPlatform);
|
|
depsTargetTargetPropagated = map (stdenv.lib.getOutput "out") (libDeps targetPlatform);
|
|
|
|
# required, because otherwise all symbols from HSffi.o are stripped, and
|
|
# that in turn causes GHCi to abort
|
|
stripDebugFlags = [ "-S" ] ++ stdenv.lib.optional (!targetPlatform.isDarwin) "--keep-file-symbols";
|
|
|
|
checkTarget = "test";
|
|
|
|
hardeningDisable = [ "format" ];
|
|
|
|
postInstall = ''
|
|
for bin in "$out"/lib/${name}/bin/*; do
|
|
isELF "$bin" || continue
|
|
paxmark m "$bin"
|
|
done
|
|
|
|
# Install the bash completion file.
|
|
install -D -m 444 utils/completion/ghc.bash $out/share/bash-completion/completions/${targetPrefix}ghc
|
|
|
|
# Patch scripts to include "readelf" and "cat" in $PATH.
|
|
for i in "$out/bin/"*; do
|
|
test ! -h $i || continue
|
|
egrep --quiet '^#!' <(head -n 1 $i) || continue
|
|
sed -i -e '2i export PATH="$PATH:${stdenv.lib.makeBinPath [ targetPackages.stdenv.cc.bintools coreutils ]}"' $i
|
|
done
|
|
'';
|
|
|
|
passthru = {
|
|
inherit bootPkgs targetPrefix;
|
|
|
|
inherit llvmPackages;
|
|
inherit enableShared;
|
|
|
|
# Our Cabal compiler name
|
|
haskellCompilerName = "ghc-8.5";
|
|
};
|
|
|
|
meta = {
|
|
homepage = http://haskell.org/ghc;
|
|
description = "The Glasgow Haskell Compiler";
|
|
maintainers = with stdenv.lib.maintainers; [ marcweber andres peti ];
|
|
inherit (ghc.meta) license platforms;
|
|
};
|
|
|
|
}
|