mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-14 01:33:10 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
57 lines
1.6 KiB
Nix
57 lines
1.6 KiB
Nix
{ lib, stdenv, fetchFromGitHub, fetchpatch, perl, gettext, pkg-config, libidn2, libiconv }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
version = "5.5.23";
|
|
pname = "whois";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "rfc1036";
|
|
repo = "whois";
|
|
rev = "v${version}";
|
|
hash = "sha256-c/Mx2HXAj6mHH8rElG7+F94sSrVSL1N9HZBvaMWUjlw=";
|
|
};
|
|
|
|
patches = [
|
|
(fetchpatch {
|
|
url = "https://github.com/macports/macports-ports/raw/93de4e9fc1e5e8427bf98f48209e783a5e8fab57/net/whois/files/implicit.patch";
|
|
extraPrefix = "";
|
|
hash = "sha256-ogVylQz//tpXxPNIWIHkhghvToU1z1D1FfnUBdZLyRY=";
|
|
})
|
|
];
|
|
|
|
env = lib.optionalAttrs stdenv.hostPlatform.isDarwin {
|
|
# whois fails to link libiconv on Darwin.
|
|
NIX_LDFLAGS = "-liconv";
|
|
};
|
|
|
|
nativeBuildInputs = [ perl gettext pkg-config ];
|
|
buildInputs = [ libidn2 libiconv ];
|
|
|
|
preConfigure = ''
|
|
for i in Makefile po/Makefile; do
|
|
substituteInPlace $i --replace "prefix = /usr" "prefix = $out"
|
|
done
|
|
'';
|
|
|
|
makeFlags = [ "HAVE_ICONV=1" ];
|
|
buildFlags = [ "whois" ];
|
|
|
|
installTargets = [ "install-whois" ];
|
|
|
|
meta = with lib; {
|
|
description = "Intelligent WHOIS client from Debian";
|
|
longDescription = ''
|
|
This package provides a commandline client for the WHOIS (RFC 3912)
|
|
protocol, which queries online servers for information such as contact
|
|
details for domains and IP address assignments. It can intelligently
|
|
select the appropriate WHOIS server for most queries.
|
|
'';
|
|
|
|
homepage = "https://packages.qa.debian.org/w/whois.html";
|
|
license = licenses.gpl2Plus;
|
|
maintainers = with maintainers; [ fpletz ];
|
|
platforms = platforms.unix;
|
|
mainProgram = "whois";
|
|
};
|
|
}
|