mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-14 17:04:42 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
105 lines
2.8 KiB
Nix
105 lines
2.8 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchurl,
|
|
fetchpatch,
|
|
updateAutotoolsGnuConfigScriptsHook,
|
|
pcre,
|
|
windows ? null,
|
|
# Disable jit on Apple Silicon, https://github.com/zherczeg/sljit/issues/51
|
|
enableJit ? !(stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64),
|
|
variant ? null,
|
|
}:
|
|
|
|
assert lib.elem variant [
|
|
null
|
|
"cpp"
|
|
"pcre16"
|
|
"pcre32"
|
|
];
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname =
|
|
"pcre"
|
|
+ lib.optionalString (variant == "cpp") "-cpp"
|
|
+ lib.optionalString (variant != "cpp" && variant != null) variant;
|
|
version = "8.45";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://sourceforge/project/pcre/pcre/${version}/pcre-${version}.tar.bz2";
|
|
sha256 = "sha256-Ta5v3NK7C7bDe1+Xwzwr6VTadDmFNpzdrDVG4yGL/7g=";
|
|
};
|
|
|
|
outputs = [
|
|
"bin"
|
|
"dev"
|
|
"out"
|
|
"doc"
|
|
"man"
|
|
];
|
|
|
|
hardeningDisable = lib.optional enableJit "shadowstack";
|
|
|
|
configureFlags =
|
|
[
|
|
"--enable-unicode-properties"
|
|
"--disable-cpp"
|
|
]
|
|
++ lib.optional enableJit "--enable-jit=auto"
|
|
++ lib.optional (variant != null) "--enable-${variant}";
|
|
|
|
patches = [
|
|
# https://bugs.exim.org/show_bug.cgi?id=2173
|
|
./stacksize-detection.patch
|
|
|
|
# Fix segfaults & tests on powerpc64
|
|
(fetchpatch {
|
|
name = "sljit-ppc-icache-flush.patch";
|
|
url = "https://github.com/void-linux/void-packages/raw/d286e231ee680875ad8e80f90ea62e46f5edd812/srcpkgs/pcre/patches/ppc-icache-flush.patch";
|
|
hash = "sha256-pttmKwihLzKrAV6O4qVLp2pu4NwNJEFS/9Id8/b3nAU=";
|
|
})
|
|
];
|
|
|
|
# necessary to build on FreeBSD native pending inclusion of
|
|
# https://git.savannah.gnu.org/cgit/config.git/commit/?id=e4786449e1c26716e3f9ea182caf472e4dbc96e0
|
|
nativeBuildInputs = [ updateAutotoolsGnuConfigScriptsHook ];
|
|
|
|
preCheck = ''
|
|
patchShebangs RunGrepTest
|
|
'';
|
|
|
|
doCheck =
|
|
!(with stdenv.hostPlatform; isCygwin || isFreeBSD) && stdenv.hostPlatform == stdenv.buildPlatform;
|
|
# XXX: test failure on Cygwin
|
|
# we are running out of stack on both freeBSDs on Hydra
|
|
|
|
postFixup =
|
|
''
|
|
moveToOutput bin/pcre-config "$dev"
|
|
''
|
|
+ lib.optionalString (variant != null) ''
|
|
ln -sf -t "$out/lib/" '${pcre.out}'/lib/libpcre{,posix}.{so.*.*.*,*dylib,*a}
|
|
'';
|
|
|
|
meta = {
|
|
homepage = "http://www.pcre.org/";
|
|
description = "Library for Perl Compatible Regular Expressions";
|
|
license = lib.licenses.bsd3;
|
|
|
|
longDescription = ''
|
|
The PCRE library is a set of functions that implement regular
|
|
expression pattern matching using the same syntax and semantics as
|
|
Perl 5. PCRE has its own native API, as well as a set of wrapper
|
|
functions that correspond to the POSIX regular expression API. The
|
|
PCRE library is free, even for building proprietary software.
|
|
'';
|
|
|
|
platforms = lib.platforms.all;
|
|
maintainers = [ ];
|
|
pkgConfigModules = [
|
|
"libpcre"
|
|
"libpcreposix"
|
|
];
|
|
};
|
|
}
|