mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-27 08:04:14 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
66 lines
2.0 KiB
Nix
66 lines
2.0 KiB
Nix
{ lib, stdenv, fetchzip, fetchurl, xorg
|
|
, withBigAtlas ? true
|
|
, withEphemeris ? true
|
|
, withMoonsEphemeris ? true
|
|
}:
|
|
stdenv.mkDerivation {
|
|
pname = "astrolog";
|
|
version = "7.70";
|
|
|
|
src = fetchzip {
|
|
url = "https://www.astrolog.org/ftp/ast77src.zip";
|
|
hash = "sha256-rG7njEtnHwUDqWstj0bQxm2c9CbsOmWOCYs0FtiVoJE=";
|
|
stripRoot = false;
|
|
};
|
|
|
|
patchPhase = ''
|
|
sed -i "s:~/astrolog:$out/astrolog:g" astrolog.h
|
|
substituteInPlace Makefile --replace cc "$CC" --replace strip "$STRIP"
|
|
'';
|
|
|
|
buildInputs = [ xorg.libX11 ];
|
|
env.NIX_CFLAGS_COMPILE = "-Wno-format-security";
|
|
|
|
installPhase =
|
|
let
|
|
ephemeris = fetchzip {
|
|
url = "http://astrolog.org/ftp/ephem/astephem.zip";
|
|
sha256 = "1mwvpvfk3lxjcc79zvwl4ypqzgqzipnc01cjldxrmx56xkc35zn7";
|
|
stripRoot = false;
|
|
};
|
|
moonsEphemeris = fetchzip {
|
|
url = "https://www.astrolog.org/ftp/ephem/moons/sepm.zip";
|
|
sha256 = "0labcidm8mrwvww93nwpp5738m9ff9q48cqzbgd18xny1jf6f8xd";
|
|
stripRoot = false;
|
|
};
|
|
atlas = fetchurl {
|
|
url = "http://astrolog.org/ftp/atlas/atlasbig.as";
|
|
sha256 = "001bmqyldsbk4bdliqfl4a9ydrh1ff13wccvfniwaxlmvkridx2q";
|
|
};
|
|
in ''
|
|
mkdir -p $out/bin $out/astrolog
|
|
cp *.as $out/astrolog
|
|
install astrolog $out/bin
|
|
${lib.optionalString withBigAtlas "cp ${atlas} $out/astrolog/atlas.as"}
|
|
${lib.optionalString withEphemeris ''
|
|
sed -i "/-Yi1/s#\".*\"#\"$out/ephemeris\"#" $out/astrolog/astrolog.as
|
|
mkdir -p $out/ephemeris
|
|
cp -r ${ephemeris}/*.se1 $out/ephemeris
|
|
''}
|
|
${lib.optionalString withMoonsEphemeris ''
|
|
sed -i "/-Yi1/s#\".*\"#\"$out/ephemeris\"#" $out/astrolog/astrolog.as
|
|
mkdir -p $out/ephemeris
|
|
cp -r ${moonsEphemeris}/*.se1 $out/ephemeris
|
|
''}
|
|
'';
|
|
|
|
meta = with lib; {
|
|
maintainers = [ maintainers.kmein ];
|
|
homepage = "https://astrolog.org/astrolog.htm";
|
|
description = "Freeware astrology program";
|
|
mainProgram = "astrolog";
|
|
platforms = platforms.linux;
|
|
license = licenses.gpl2Plus;
|
|
};
|
|
}
|