mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-23 15:33:13 +00:00
6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
90 lines
2.7 KiB
Nix
90 lines
2.7 KiB
Nix
{ config, lib, options, pkgs, ... }:
|
|
|
|
let
|
|
inherit (lib) literalExpression mkOption mkEnableOption types mkIf mkMerge optional versionOlder;
|
|
cfg = config.hardware.system76;
|
|
opt = options.hardware.system76;
|
|
|
|
kpkgs = config.boot.kernelPackages;
|
|
modules = [ "system76" "system76-io" ] ++ (optional (versionOlder kpkgs.kernel.version "5.5") "system76-acpi");
|
|
modulePackages = map (m: kpkgs.${m}) modules;
|
|
moduleConfig = mkIf cfg.kernel-modules.enable {
|
|
boot.extraModulePackages = modulePackages;
|
|
|
|
boot.kernelModules = modules;
|
|
|
|
services.udev.packages = modulePackages;
|
|
};
|
|
|
|
firmware-pkg = pkgs.system76-firmware;
|
|
firmwareConfig = mkIf cfg.firmware-daemon.enable {
|
|
# Make system76-firmware-cli usable by root from the command line.
|
|
environment.systemPackages = [ firmware-pkg ];
|
|
|
|
services.dbus.packages = [ firmware-pkg ];
|
|
|
|
systemd.services.system76-firmware-daemon = {
|
|
description = "The System76 Firmware Daemon";
|
|
|
|
serviceConfig = {
|
|
ExecStart = "${firmware-pkg}/bin/system76-firmware-daemon";
|
|
|
|
Restart = "on-failure";
|
|
};
|
|
|
|
wantedBy = [ "multi-user.target" ];
|
|
};
|
|
};
|
|
|
|
power-pkg = config.boot.kernelPackages.system76-power;
|
|
powerConfig = mkIf cfg.power-daemon.enable {
|
|
# Make system76-power usable by root from the command line.
|
|
environment.systemPackages = [ power-pkg ];
|
|
|
|
services.dbus.packages = [ power-pkg ];
|
|
|
|
systemd.services.system76-power = {
|
|
description = "System76 Power Daemon";
|
|
serviceConfig = {
|
|
ExecStart = "${power-pkg}/bin/system76-power daemon";
|
|
Restart = "on-failure";
|
|
Type = "dbus";
|
|
BusName = "com.system76.PowerDaemon";
|
|
};
|
|
wantedBy = [ "multi-user.target" ];
|
|
};
|
|
};
|
|
in {
|
|
options = {
|
|
hardware.system76 = {
|
|
enableAll = mkEnableOption "all recommended configuration for system76 systems";
|
|
|
|
firmware-daemon.enable = mkOption {
|
|
default = cfg.enableAll;
|
|
defaultText = literalExpression "config.${opt.enableAll}";
|
|
example = true;
|
|
description = "Whether to enable the system76 firmware daemon";
|
|
type = types.bool;
|
|
};
|
|
|
|
kernel-modules.enable = mkOption {
|
|
default = cfg.enableAll;
|
|
defaultText = literalExpression "config.${opt.enableAll}";
|
|
example = true;
|
|
description = "Whether to make the system76 out-of-tree kernel modules available";
|
|
type = types.bool;
|
|
};
|
|
|
|
power-daemon.enable = mkOption {
|
|
default = cfg.enableAll;
|
|
defaultText = literalExpression "config.${opt.enableAll}";
|
|
example = true;
|
|
description = "Whether to enable the system76 power daemon";
|
|
type = types.bool;
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkMerge [ moduleConfig firmwareConfig powerConfig ];
|
|
}
|