mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-01 02:23:54 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
87 lines
2.0 KiB
Nix
87 lines
2.0 KiB
Nix
{ stdenv, lib, fetchFromGitHub, makeWrapper, installShellFiles, bash, curl, git, writeScript }:
|
|
|
|
let
|
|
asdfReshimFile = writeScript "asdf-reshim" ''
|
|
#!/usr/bin/env bash
|
|
|
|
# asdf-vm create "shim" file like this:
|
|
#
|
|
# exec $ASDF_DIR/bin/asdf exec "node" "$@"
|
|
#
|
|
# So we should reshim all installed versions every time shell initialized,
|
|
# because $out always change
|
|
|
|
asdfDir="''${ASDF_DIR:-$HOME/.asdf}"
|
|
asdfDataDir="''${ASDF_DATA_DIR:-$HOME/.asdf}"
|
|
|
|
prevAsdfDirFilePath="$asdfDataDir/.nix-prev-asdf-dir-path"
|
|
|
|
if [ -r "$prevAsdfDirFilePath" ]; then
|
|
prevAsdfDir="$(cat "$prevAsdfDirFilePath")"
|
|
else
|
|
prevAsdfDir=""
|
|
fi
|
|
|
|
if [ "$prevAsdfDir" != "$asdfDir" ]; then
|
|
rm -rf "$asdfDataDir"/shims
|
|
"$asdfDir"/bin/asdf reshim
|
|
echo "$asdfDir" > "$prevAsdfDirFilePath"
|
|
fi
|
|
'';
|
|
|
|
asdfPrepareFile = writeScript "asdf-prepare" ''
|
|
ASDF_DIR="@asdfDir@"
|
|
|
|
source "$ASDF_DIR/asdf.sh"
|
|
${asdfReshimFile}
|
|
'';
|
|
in stdenv.mkDerivation rec {
|
|
pname = "asdf-vm";
|
|
version = "0.14.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "asdf-vm";
|
|
repo = "asdf";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-1dacsAoZVwoQv8+V4FrjRLa7awLIZchlhkuET0wTO7w=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
makeWrapper
|
|
installShellFiles
|
|
];
|
|
|
|
buildInputs = [
|
|
bash
|
|
curl
|
|
git
|
|
];
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/share/asdf-vm
|
|
cp -r . $out/share/asdf-vm
|
|
|
|
mkdir -p $out/etc/profile.d
|
|
substitute ${asdfPrepareFile} $out/etc/profile.d/asdf-prepare.sh \
|
|
--replace "@asdfDir@" "$out/share/asdf-vm"
|
|
|
|
mkdir -p $out/bin
|
|
makeWrapper $out/share/asdf-vm/bin/asdf $out/bin/asdf \
|
|
--set ASDF_DIR $out/share/asdf-vm
|
|
|
|
installShellCompletion --cmd asdf \
|
|
--zsh completions/_asdf \
|
|
--fish completions/asdf.fish \
|
|
--bash completions/asdf.bash
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Extendable version manager with support for Ruby, Node.js, Erlang & more";
|
|
homepage = "https://asdf-vm.com/";
|
|
license = licenses.mit;
|
|
maintainers = [ maintainers.c4605 ];
|
|
mainProgram = "asdf";
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|