mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-03 03:23:17 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
79 lines
1.8 KiB
Nix
79 lines
1.8 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
autoreconfHook,
|
|
writeShellScript,
|
|
pkg-config,
|
|
texinfo,
|
|
pcre2,
|
|
swig,
|
|
libxml2,
|
|
ncurses,
|
|
enablePython ? false,
|
|
python ? null,
|
|
}:
|
|
let
|
|
isPython3 = enablePython && python.pythonAtLeast "3";
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = "libredwg";
|
|
version = "0.13.3";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "LibreDWG";
|
|
repo = pname;
|
|
rev = version;
|
|
hash = "sha256-FlBHwNsqVSBE8dTDewoKkCbs8Jd/4d69MPpEFzg6Ruc=";
|
|
fetchSubmodules = true;
|
|
};
|
|
|
|
postPatch =
|
|
let
|
|
printVersion = writeShellScript "print-version" ''
|
|
echo -n ${lib.escapeShellArg version}
|
|
'';
|
|
in
|
|
''
|
|
# avoid git dependency
|
|
cp ${printVersion} build-aux/git-version-gen
|
|
'';
|
|
|
|
preConfigure = lib.optionalString (stdenv.hostPlatform.isDarwin && enablePython) ''
|
|
# prevent configure picking up stack_size from distutils.sysconfig
|
|
export PYTHON_EXTRA_LDFLAGS=" "
|
|
'';
|
|
|
|
nativeBuildInputs = [
|
|
autoreconfHook
|
|
pkg-config
|
|
texinfo
|
|
] ++ lib.optional enablePython swig;
|
|
|
|
buildInputs =
|
|
[ pcre2 ]
|
|
++ lib.optionals enablePython [ python ]
|
|
# configurePhase fails with python 3 when ncurses is missing
|
|
++ lib.optional isPython3 ncurses;
|
|
|
|
# prevent python tests from running when not building with python
|
|
configureFlags = lib.optional (!enablePython) "--disable-python";
|
|
|
|
# FAIL: alive.test
|
|
doCheck = !stdenv.hostPlatform.isLinux;
|
|
|
|
# the "xmlsuite" test requires the libxml2 c library as well as the python module
|
|
nativeCheckInputs = lib.optionals enablePython [
|
|
libxml2
|
|
libxml2.dev
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "Free implementation of the DWG file format";
|
|
homepage = "https://savannah.gnu.org/projects/libredwg/";
|
|
maintainers = with maintainers; [ tweber ];
|
|
license = licenses.gpl3Plus;
|
|
platforms = platforms.all;
|
|
};
|
|
}
|