mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-03 20:33:21 +00:00
730a9a04fa
This was removed in e29b0da9c7, because
it was felt it was ambiguous whether isBSD should remove Darwin.
I think it should be reintroduced. Packages sometimes have their own
concepts of "is BSD" e.g. Lua, and these almost never include Darwin,
so let's keep Darwin excluded.
Without a way to say "is this BSD", one has to list all flavours of
BSD seperately, even though fundamentally they're still extremely
similar. I don't want to have to write the following!
stdenv.isFreeBSD || stdenv.isNetBSD || stdenv.isOpenBSD || stdenv.isDragonFlyBSD
Additionally, we've had stdenv.hostPlatform.isBSD this whole time, and
it hasn't hurt anything.
62 lines
2.0 KiB
Nix
62 lines
2.0 KiB
Nix
{ lib, stdenv, fetchFromGitLab, rustPlatform, cmake, pkg-config, openssl
|
|
, darwin, installShellFiles
|
|
|
|
, x11Support ? stdenv.isLinux || stdenv.hostPlatform.isBSD
|
|
, xclip ? null, xsel ? null
|
|
, preferXsel ? false # if true and xsel is non-null, use it instead of xclip
|
|
}:
|
|
|
|
let
|
|
usesX11 = stdenv.isLinux || stdenv.isBSD;
|
|
in
|
|
|
|
assert (x11Support && usesX11) -> xclip != null || xsel != null;
|
|
|
|
with rustPlatform;
|
|
|
|
buildRustPackage rec {
|
|
pname = "ffsend";
|
|
version = "0.2.68";
|
|
|
|
src = fetchFromGitLab {
|
|
owner = "timvisee";
|
|
repo = "ffsend";
|
|
rev = "v${version}";
|
|
sha256 = "0ga1v4s8ks2v632mim8ljya0gi2j8bbwj98yfm3g00p0z1i526qk";
|
|
};
|
|
|
|
cargoSha256 = "1n9pf29xid6jcas5yx94k4cpmqgx0kpqq7gwf83jisjywxzygh6w";
|
|
|
|
nativeBuildInputs = [ cmake pkg-config installShellFiles ];
|
|
buildInputs =
|
|
if stdenv.isDarwin then (with darwin.apple_sdk.frameworks; [ CoreFoundation CoreServices Security AppKit ])
|
|
else [ openssl ];
|
|
|
|
preBuild = lib.optionalString (x11Support && usesX11) (
|
|
if preferXsel && xsel != null then ''
|
|
export XSEL_PATH="${xsel}/bin/xsel"
|
|
'' else ''
|
|
export XCLIP_PATH="${xclip}/bin/xclip"
|
|
''
|
|
);
|
|
|
|
postInstall = ''
|
|
installShellCompletion contrib/completions/ffsend.{bash,fish} --zsh contrib/completions/_ffsend
|
|
'';
|
|
# There's also .elv and .ps1 completion files but I don't know where to install those
|
|
|
|
meta = with lib; {
|
|
description = "Easily and securely share files from the command line. A fully featured Firefox Send client";
|
|
longDescription = ''
|
|
Easily and securely share files and directories from the command line through a safe, private
|
|
and encrypted link using a single simple command. Files are shared using the Send service and
|
|
may be up to 2GB. Others are able to download these files with this tool, or through their
|
|
web browser.
|
|
'';
|
|
homepage = "https://gitlab.com/timvisee/ffsend";
|
|
license = licenses.gpl3;
|
|
maintainers = with maintainers; [ lilyball equirosa ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|