mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-27 08:04:14 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
62 lines
1.7 KiB
Nix
62 lines
1.7 KiB
Nix
# This file chooses a sane default stdenv given the system, platform, etc.
|
|
#
|
|
# Rather than returning a stdenv, this returns a list of functions---one per
|
|
# each bootstrapping stage. See `./booter.nix` for exactly what this list should
|
|
# contain.
|
|
|
|
{
|
|
# Args just for stdenvs' usage
|
|
lib,
|
|
# Args to pass on to the pkgset builder, too
|
|
localSystem,
|
|
crossSystem,
|
|
config,
|
|
overlays,
|
|
crossOverlays ? [ ],
|
|
}@args:
|
|
|
|
let
|
|
# The native (i.e., impure) build environment. This one uses the
|
|
# tools installed on the system outside of the Nix environment,
|
|
# i.e., the stuff in /bin, /usr/bin, etc. This environment should
|
|
# be used with care, since many Nix packages will not build properly
|
|
# with it (e.g., because they require GNU Make).
|
|
stagesNative = import ./native args;
|
|
|
|
# The Nix build environment.
|
|
stagesNix = import ./nix (args // { bootStages = stagesNative; });
|
|
|
|
stagesFreeBSD = import ./freebsd args;
|
|
|
|
# On Linux systems, the standard build environment consists of Nix-built
|
|
# instances glibc and the `standard' Unix tools, i.e., the Posix utilities,
|
|
# the GNU C compiler, and so on.
|
|
stagesLinux = import ./linux args;
|
|
|
|
stagesDarwin = import ./darwin args;
|
|
|
|
stagesCross = import ./cross args;
|
|
|
|
stagesCustom = import ./custom args;
|
|
|
|
in
|
|
# Select the appropriate stages for the platform `system'.
|
|
if crossSystem != localSystem || crossOverlays != [ ] then
|
|
stagesCross
|
|
else if config ? replaceStdenv then
|
|
stagesCustom
|
|
else if localSystem.isLinux then
|
|
stagesLinux
|
|
else if localSystem.isDarwin then
|
|
stagesDarwin
|
|
# misc special cases
|
|
else
|
|
{
|
|
# switch
|
|
x86_64-solaris = stagesNix;
|
|
i686-cygwin = stagesNative;
|
|
x86_64-cygwin = stagesNative;
|
|
x86_64-freebsd = stagesFreeBSD;
|
|
}
|
|
.${localSystem.system} or stagesNative
|