mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-14 17:04:42 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
86 lines
1.8 KiB
Nix
86 lines
1.8 KiB
Nix
{
|
|
lib,
|
|
stdenvNoCC,
|
|
buildPackages,
|
|
cacert,
|
|
subversion,
|
|
glibcLocales,
|
|
sshSupport ? true,
|
|
openssh ? null,
|
|
}:
|
|
|
|
{
|
|
url,
|
|
rev ? "HEAD",
|
|
sha256 ? "",
|
|
hash ? "",
|
|
ignoreExternals ? false,
|
|
ignoreKeywords ? false,
|
|
name ? null,
|
|
preferLocalBuild ? true,
|
|
}:
|
|
|
|
assert sshSupport -> openssh != null;
|
|
|
|
let
|
|
repoName =
|
|
let
|
|
fst = lib.head;
|
|
snd = l: lib.head (lib.tail l);
|
|
trd = l: lib.head (lib.tail (lib.tail l));
|
|
path_ =
|
|
(p: if lib.head p == "" then lib.tail p else p) # ~ drop final slash if any
|
|
(lib.reverseList (lib.splitString "/" url));
|
|
path = [ (lib.removeSuffix "/" (lib.head path_)) ] ++ (lib.tail path_);
|
|
in
|
|
# ../repo/trunk -> repo
|
|
if fst path == "trunk" then
|
|
snd path
|
|
# ../repo/branches/branch -> repo-branch
|
|
else if snd path == "branches" then
|
|
"${trd path}-${fst path}"
|
|
# ../repo/tags/tag -> repo-tag
|
|
else if snd path == "tags" then
|
|
"${trd path}-${fst path}"
|
|
# ../repo (no trunk) -> repo
|
|
else
|
|
fst path;
|
|
|
|
name_ = if name == null then "${repoName}-r${toString rev}" else name;
|
|
in
|
|
|
|
if hash != "" && sha256 != "" then
|
|
throw "Only one of sha256 or hash can be set"
|
|
else
|
|
stdenvNoCC.mkDerivation {
|
|
name = name_;
|
|
builder = ./builder.sh;
|
|
nativeBuildInputs = [
|
|
cacert
|
|
subversion
|
|
glibcLocales
|
|
] ++ lib.optional sshSupport openssh;
|
|
|
|
SVN_SSH = if sshSupport then "${buildPackages.openssh}/bin/ssh" else null;
|
|
|
|
outputHashAlgo = if hash != "" then null else "sha256";
|
|
outputHashMode = "recursive";
|
|
outputHash =
|
|
if hash != "" then
|
|
hash
|
|
else if sha256 != "" then
|
|
sha256
|
|
else
|
|
lib.fakeSha256;
|
|
|
|
inherit
|
|
url
|
|
rev
|
|
ignoreExternals
|
|
ignoreKeywords
|
|
;
|
|
|
|
impureEnvVars = lib.fetchers.proxyImpureEnvVars;
|
|
inherit preferLocalBuild;
|
|
}
|