mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-02-11 22:54:17 +00:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
80 lines
2.8 KiB
Nix
80 lines
2.8 KiB
Nix
{ lib
|
||
, stdenv
|
||
, fetchurl
|
||
, autoreconfHook
|
||
, guileSupport ? false, guile
|
||
# avoid guile depend on bootstrap to prevent dependency cycles
|
||
, inBootstrap ? false
|
||
, pkg-config
|
||
, gnumake
|
||
}:
|
||
|
||
let
|
||
guileEnabled = guileSupport && !inBootstrap;
|
||
in
|
||
|
||
stdenv.mkDerivation rec {
|
||
pname = "gnumake";
|
||
version = "4.4.1";
|
||
|
||
src = fetchurl {
|
||
url = "mirror://gnu/make/make-${version}.tar.gz";
|
||
sha256 = "sha256-3Rb7HWe/q3mnL16DkHNcSePo5wtJRaFasfgd23hlj7M=";
|
||
};
|
||
|
||
# To update patches:
|
||
# $ version=4.4.1
|
||
# $ git clone https://git.savannah.gnu.org/git/make.git
|
||
# $ cd make && git checkout -b nixpkgs $version
|
||
# $ git am --directory=../patches
|
||
# $ # make changes, resolve conflicts, etc.
|
||
# $ git format-patch --output-directory ../patches --diff-algorithm=histogram $version
|
||
#
|
||
# TODO: stdenv’s setup.sh should be aware of patch directories. It’s very
|
||
# convenient to keep them in a separate directory but we can defer listing the
|
||
# directory until derivation realization to avoid unnecessary Nix evaluations.
|
||
patches = lib.filesystem.listFilesRecursive ./patches;
|
||
|
||
nativeBuildInputs = [ autoreconfHook pkg-config ];
|
||
buildInputs = lib.optionals guileEnabled [ guile ];
|
||
|
||
configureFlags = lib.optional guileEnabled "--with-guile"
|
||
|
||
# Make uses this test to decide whether it should keep track of
|
||
# subseconds. Apple made this possible with APFS and macOS 10.13.
|
||
# However, we still support macOS 10.11 and 10.12. Binaries built
|
||
# in Nixpkgs will be unable to use futimens to set mtime less than
|
||
# a second. So, tell Make to ignore nanoseconds in mtime here by
|
||
# overriding the autoconf test for the struct.
|
||
# See https://github.com/NixOS/nixpkgs/issues/51221 for discussion.
|
||
++ lib.optional stdenv.hostPlatform.isDarwin "ac_cv_struct_st_mtim_nsec=no";
|
||
|
||
outputs = [ "out" "man" "info" ];
|
||
separateDebugInfo = true;
|
||
|
||
passthru.tests = {
|
||
# make sure that the override doesn't break bootstrapping
|
||
gnumakeWithGuile = gnumake.override { guileSupport = true; };
|
||
};
|
||
|
||
meta = with lib; {
|
||
description = "Tool to control the generation of non-source files from sources";
|
||
longDescription = ''
|
||
Make is a tool which controls the generation of executables and
|
||
other non-source files of a program from the program's source files.
|
||
|
||
Make gets its knowledge of how to build your program from a file
|
||
called the makefile, which lists each of the non-source files and
|
||
how to compute it from other files. When you write a program, you
|
||
should write a makefile for it, so that it is possible to use Make
|
||
to build and install the program.
|
||
'';
|
||
homepage = "https://www.gnu.org/software/make/";
|
||
|
||
license = licenses.gpl3Plus;
|
||
maintainers = [ ];
|
||
mainProgram = "make";
|
||
platforms = platforms.all;
|
||
};
|
||
}
|