mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-03 12:23:02 +00:00
ef176dcf7e
conversions were done using https://github.com/pennae/nix-doc-munge using (probably) rev f34e145 running nix-doc-munge nixos/**/*.nix nix-doc-munge --import nixos/**/*.nix the tool ensures that only changes that could affect the generated manual *but don't* are committed, other changes require manual review and are discarded.
69 lines
2.0 KiB
Nix
69 lines
2.0 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.spotifyd;
|
|
toml = pkgs.formats.toml {};
|
|
warnConfig =
|
|
if cfg.config != ""
|
|
then lib.trace "Using the stringly typed .config attribute is discouraged. Use the TOML typed .settings attribute instead."
|
|
else id;
|
|
spotifydConf =
|
|
if cfg.settings != {}
|
|
then toml.generate "spotify.conf" cfg.settings
|
|
else warnConfig (pkgs.writeText "spotifyd.conf" cfg.config);
|
|
in
|
|
{
|
|
options = {
|
|
services.spotifyd = {
|
|
enable = mkEnableOption (lib.mdDoc "spotifyd, a Spotify playing daemon");
|
|
|
|
config = mkOption {
|
|
default = "";
|
|
type = types.lines;
|
|
description = lib.mdDoc ''
|
|
(Deprecated) Configuration for Spotifyd. For syntax and directives, see
|
|
<https://github.com/Spotifyd/spotifyd#Configuration>.
|
|
'';
|
|
};
|
|
|
|
settings = mkOption {
|
|
default = {};
|
|
type = toml.type;
|
|
example = { global.bitrate = 320; };
|
|
description = lib.mdDoc ''
|
|
Configuration for Spotifyd. For syntax and directives, see
|
|
<https://github.com/Spotifyd/spotifyd#Configuration>.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
{
|
|
assertion = cfg.config == "" || cfg.settings == {};
|
|
message = "At most one of the .config attribute and the .settings attribute may be set";
|
|
}
|
|
];
|
|
|
|
systemd.services.spotifyd = {
|
|
wantedBy = [ "multi-user.target" ];
|
|
after = [ "network-online.target" "sound.target" ];
|
|
description = "spotifyd, a Spotify playing daemon";
|
|
environment.SHELL = "/bin/sh";
|
|
serviceConfig = {
|
|
ExecStart = "${pkgs.spotifyd}/bin/spotifyd --no-daemon --cache-path /var/cache/spotifyd --config-path ${spotifydConf}";
|
|
Restart = "always";
|
|
RestartSec = 12;
|
|
DynamicUser = true;
|
|
CacheDirectory = "spotifyd";
|
|
SupplementaryGroups = ["audio"];
|
|
};
|
|
};
|
|
};
|
|
|
|
meta.maintainers = [ maintainers.anderslundstedt ];
|
|
}
|