mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-29 09:04:17 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
94 lines
2.2 KiB
Nix
94 lines
2.2 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, curl
|
|
, jdk
|
|
, libedit
|
|
, srt
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "tsduck";
|
|
version = "3.31-2761";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "tsduck";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
sha256 = "sha256-268TKCh3naebbw+sOQ6d4N/zl7UEVtc3l3flFAYHDU4=";
|
|
};
|
|
|
|
buildInputs = [
|
|
curl
|
|
libedit
|
|
srt
|
|
jdk
|
|
];
|
|
|
|
# remove tests which call out to https://tsduck.io/download/test/...
|
|
postPatch = ''
|
|
sed -i"" \
|
|
-e '/TSUNIT_TEST(testMasterPlaylist);/ d' \
|
|
-e '/TSUNIT_TEST(testMasterPlaylistWithAlternate);/ d' \
|
|
-e '/TSUNIT_TEST(testMediaPlaylist);/ d' \
|
|
src/utest/utestHLS.cpp
|
|
|
|
sed -i"" \
|
|
-e '/TSUNIT_TEST(testBetterSystemRandomGenerator);/ d' \
|
|
src/utest/utestSystemRandomGenerator.cpp
|
|
|
|
sed -i"" \
|
|
-e '/TSUNIT_ASSERT(request.downloadBinaryContent/ d' \
|
|
-e '/TSUNIT_ASSERT(!request.downloadBinaryContent/ d' \
|
|
-e '/TSUNIT_TEST(testGitHub);/ d' \
|
|
-e '/TSUNIT_TEST(testGoogle);/ d' \
|
|
-e '/TSUNIT_TEST(testNoRedirection);/ d' \
|
|
-e '/TSUNIT_TEST(testReadMeFile);/ d' \
|
|
src/utest/utestWebRequest.cpp
|
|
|
|
sed -i"" \
|
|
-e '/TSUNIT_TEST(testHomeDirectory);/ d' \
|
|
src/utest/utestSysUtils.cpp
|
|
|
|
sed -i"" \
|
|
-e '/TSUNIT_TEST(testIPv4Address);/ d' \
|
|
-e '/TSUNIT_TEST(testIPv4AddressConstructors);/ d' \
|
|
-e '/TSUNIT_TEST(testIPv4SocketAddressConstructors);/ d' \
|
|
-e '/TSUNIT_TEST(testTCPSocket);/ d' \
|
|
-e '/TSUNIT_TEST(testUDPSocket);/ d' \
|
|
src/utest/utestNetworking.cpp
|
|
'';
|
|
|
|
enableParallelBuilding = true;
|
|
makeFlags = [
|
|
"NODEKTEC=1"
|
|
"NOHIDES=1"
|
|
"NOPCSC=1"
|
|
"NORIST=1"
|
|
"NOVATEK=1"
|
|
] ++ installFlags;
|
|
|
|
checkTarget = "test";
|
|
doCheck = true;
|
|
|
|
installFlags = [
|
|
"SYSROOT=${placeholder "out"}"
|
|
"SYSPREFIX=/"
|
|
"USRLIBDIR=/lib"
|
|
];
|
|
installTargets = [
|
|
"install-tools"
|
|
"install-devel"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "MPEG Transport Stream Toolkit";
|
|
homepage = "https://github.com/tsduck/tsduck";
|
|
license = licenses.bsd2;
|
|
maintainers = with maintainers; [ siriobalmelli ];
|
|
platforms = platforms.all;
|
|
# never built on aarch64-darwin, x86_64-darwin since first introduction in nixpkgs
|
|
broken = stdenv.hostPlatform.isDarwin;
|
|
};
|
|
}
|