mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-29 09:04:17 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
65 lines
2.4 KiB
Nix
65 lines
2.4 KiB
Nix
{ lib, stdenv, fetchFromGitea, perl, perlPackages, makeWrapper
|
|
, ps, dnsutils # dig is recommended for multiple categories
|
|
, withRecommends ? false # Install (almost) all recommended tools (see --recommends)
|
|
, withRecommendedSystemPrograms ? withRecommends, util-linuxMinimal, dmidecode
|
|
, file, hddtemp, iproute2, ipmitool, usbutils, kmod, lm_sensors, smartmontools
|
|
, binutils, tree, upower, pciutils
|
|
, withRecommendedDisplayInformationPrograms ? withRecommends, mesa-demos, xorg
|
|
}:
|
|
|
|
let
|
|
prefixPath = programs:
|
|
"--prefix PATH ':' '${lib.makeBinPath programs}'";
|
|
recommendedSystemPrograms = lib.optionals withRecommendedSystemPrograms [
|
|
util-linuxMinimal dmidecode file hddtemp iproute2 ipmitool usbutils kmod
|
|
lm_sensors smartmontools binutils tree upower pciutils
|
|
];
|
|
recommendedDisplayInformationPrograms = lib.optionals
|
|
withRecommendedDisplayInformationPrograms
|
|
([ mesa-demos ] ++ (with xorg; [ xdpyinfo xprop xrandr ]));
|
|
programs = [ ps dnsutils ] # Core programs
|
|
++ recommendedSystemPrograms
|
|
++ recommendedDisplayInformationPrograms;
|
|
in stdenv.mkDerivation rec {
|
|
pname = "inxi";
|
|
version = "3.3.35-1";
|
|
|
|
src = fetchFromGitea {
|
|
domain = "codeberg.org";
|
|
owner = "smxi";
|
|
repo = "inxi";
|
|
rev = version;
|
|
hash = "sha256-wWG/fs+tZIiFI+dcqfwXeh9RxT2zJDiAZoizhAAu60Q=";
|
|
};
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
buildInputs = [ perl ];
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/bin
|
|
cp inxi $out/bin/
|
|
wrapProgram $out/bin/inxi \
|
|
--set PERL5LIB "${perlPackages.makePerlPath (with perlPackages; [ CpanelJSONXS ])}" \
|
|
${prefixPath programs}
|
|
mkdir -p $out/share/man/man1
|
|
cp inxi.1 $out/share/man/man1/
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Full featured CLI system information tool";
|
|
longDescription = ''
|
|
inxi is a command line system information script built for console and
|
|
IRC. It is also used a debugging tool for forum technical support to
|
|
quickly ascertain users' system configurations and hardware. inxi shows
|
|
system hardware, CPU, drivers, Xorg, Desktop, Kernel, gcc version(s),
|
|
Processes, RAM usage, and a wide variety of other useful information.
|
|
'';
|
|
homepage = "https://smxi.org/docs/inxi.htm";
|
|
changelog = "https://github.com/smxi/inxi/blob/${version}/inxi.changelog";
|
|
license = licenses.gpl3Plus;
|
|
platforms = platforms.unix;
|
|
maintainers = [ ];
|
|
mainProgram = "inxi";
|
|
};
|
|
}
|