mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-16 02:33:25 +00:00
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
100 lines
2.9 KiB
Nix
100 lines
2.9 KiB
Nix
{ config, pkgs, lib, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.teleport;
|
|
settingsYaml = pkgs.formats.yaml { };
|
|
in
|
|
{
|
|
options = {
|
|
services.teleport = with lib.types; {
|
|
enable = mkEnableOption "the Teleport service";
|
|
|
|
settings = mkOption {
|
|
type = settingsYaml.type;
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
teleport = {
|
|
nodename = "client";
|
|
advertise_ip = "192.168.1.2";
|
|
auth_token = "60bdc117-8ff4-478d-95e4-9914597847eb";
|
|
auth_servers = [ "192.168.1.1:3025" ];
|
|
log.severity = "DEBUG";
|
|
};
|
|
ssh_service = {
|
|
enabled = true;
|
|
labels = {
|
|
role = "client";
|
|
};
|
|
};
|
|
proxy_service.enabled = false;
|
|
auth_service.enabled = false;
|
|
}
|
|
'';
|
|
description = lib.mdDoc ''
|
|
Contents of the `teleport.yaml` config file.
|
|
The `--config` arguments will only be passed if this set is not empty.
|
|
|
|
See <https://goteleport.com/docs/setup/reference/config/>.
|
|
'';
|
|
};
|
|
|
|
insecure.enable = mkEnableOption ''
|
|
starting teleport in insecure mode.
|
|
|
|
This is dangerous!
|
|
Sensitive information will be logged to console and certificates will not be verified.
|
|
Proceed with caution!
|
|
|
|
Teleport starts with disabled certificate validation on Proxy Service, validation still occurs on Auth Service
|
|
'';
|
|
|
|
diag = {
|
|
enable = mkEnableOption ''
|
|
endpoints for monitoring purposes.
|
|
|
|
See <link xlink:href="https://goteleport.com/docs/setup/admin/troubleshooting/#troubleshooting/"/>
|
|
'';
|
|
|
|
addr = mkOption {
|
|
type = str;
|
|
default = "127.0.0.1";
|
|
description = lib.mdDoc "Metrics and diagnostics address.";
|
|
};
|
|
|
|
port = mkOption {
|
|
type = int;
|
|
default = 3000;
|
|
description = lib.mdDoc "Metrics and diagnostics port.";
|
|
};
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf config.services.teleport.enable {
|
|
environment.systemPackages = [ pkgs.teleport ];
|
|
|
|
systemd.services.teleport = {
|
|
wantedBy = [ "multi-user.target" ];
|
|
after = [ "network.target" ];
|
|
serviceConfig = {
|
|
ExecStart = ''
|
|
${pkgs.teleport}/bin/teleport start \
|
|
${optionalString cfg.insecure.enable "--insecure"} \
|
|
${optionalString cfg.diag.enable "--diag-addr=${cfg.diag.addr}:${toString cfg.diag.port}"} \
|
|
${optionalString (cfg.settings != { }) "--config=${settingsYaml.generate "teleport.yaml" cfg.settings}"}
|
|
'';
|
|
ExecReload = "${pkgs.coreutils}/bin/kill -HUP $MAINPID";
|
|
LimitNOFILE = 65536;
|
|
Restart = "always";
|
|
RestartSec = "5s";
|
|
RuntimeDirectory = "teleport";
|
|
Type = "simple";
|
|
};
|
|
};
|
|
};
|
|
}
|
|
|