mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-16 02:33:25 +00:00
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
79 lines
1.9 KiB
Nix
79 lines
1.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
let
|
|
pkg = pkgs.nixops-dns;
|
|
cfg = config.services.nixops-dns;
|
|
in
|
|
|
|
{
|
|
options = {
|
|
services.nixops-dns = {
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Whether to enable the nixops-dns resolution
|
|
of NixOps virtual machines via dnsmasq and fake domain name.
|
|
'';
|
|
};
|
|
|
|
user = mkOption {
|
|
type = types.str;
|
|
description = lib.mdDoc ''
|
|
The user the nixops-dns daemon should run as.
|
|
This should be the user, which is also used for nixops and
|
|
have the .nixops directory in its home.
|
|
'';
|
|
};
|
|
|
|
domain = mkOption {
|
|
type = types.str;
|
|
description = lib.mdDoc ''
|
|
Fake domain name to resolve to NixOps virtual machines.
|
|
|
|
For example "ops" will resolve "vm.ops".
|
|
'';
|
|
default = "ops";
|
|
};
|
|
|
|
dnsmasq = mkOption {
|
|
type = types.bool;
|
|
default = true;
|
|
description = ''
|
|
Enable dnsmasq forwarding to nixops-dns. This allows to use
|
|
nixops-dns for `services.nixops-dns.domain` resolution
|
|
while forwarding the rest of the queries to original resolvers.
|
|
'';
|
|
};
|
|
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
systemd.services.nixops-dns = {
|
|
description = "nixops-dns: DNS server for resolving NixOps machines";
|
|
wantedBy = [ "multi-user.target" ];
|
|
|
|
serviceConfig = {
|
|
Type = "simple";
|
|
User = cfg.user;
|
|
ExecStart="${pkg}/bin/nixops-dns --domain=.${cfg.domain}";
|
|
};
|
|
};
|
|
|
|
services.dnsmasq = mkIf cfg.dnsmasq {
|
|
enable = true;
|
|
resolveLocalQueries = true;
|
|
servers = [
|
|
"/${cfg.domain}/127.0.0.1#5300"
|
|
];
|
|
extraConfig = ''
|
|
bind-interfaces
|
|
listen-address=127.0.0.1
|
|
'';
|
|
};
|
|
|
|
};
|
|
}
|