mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-02 19:14:14 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
39 lines
1.0 KiB
Nix
39 lines
1.0 KiB
Nix
{ lib, stdenv, fetchurl, php, which, makeWrapper, gnumake, gcc, callPackage }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "phoronix-test-suite";
|
|
version = "10.8.4";
|
|
|
|
src = fetchurl {
|
|
url = "https://phoronix-test-suite.com/releases/phoronix-test-suite-${version}.tar.gz";
|
|
sha256 = "sha256-HyCS1TbAoxk+/FPkpQ887mXA7xp40x5UBPHGY//3t/Q=";
|
|
};
|
|
|
|
buildInputs = [ php ];
|
|
nativeBuildInputs = [ which makeWrapper ];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
./install-sh $out
|
|
wrapProgram $out/bin/phoronix-test-suite \
|
|
--set PHP_BIN ${php}/bin/php \
|
|
--prefix PATH : ${lib.makeBinPath [ gnumake gcc ]}
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
passthru.tests = {
|
|
simple-execution = callPackage ./tests.nix { };
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Open-Source, Automated Benchmarking";
|
|
homepage = "https://www.phoronix-test-suite.com/";
|
|
maintainers = with maintainers; [ davidak ];
|
|
license = licenses.gpl3;
|
|
platforms = with platforms; unix;
|
|
mainProgram = "phoronix-test-suite";
|
|
};
|
|
}
|