mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-27 17:33:09 +00:00
e14c245934
When inlining a module with a problematic declaration, you usually get
get a not-so helpful error like this:
$ cat flake.nix
{
description = "A very basic flake";
inputs.nixpkgs.url = path:../.;
outputs = { self, nixpkgs }: {
nixosConfigurations.foo = nixpkgs.lib.nixosSystem {
system = "x86_64-linux";
modules = [
({ lib, ... }: { services.wrong = 2; })
{ services.nginx.enable = true; }
];
};
};
}
$ nixos-rebuild build --flake .#foo -L
error: The option `services.wrong' does not exist. Definition values:
- In `<unknown-file>': 2
While it's certainly possible to guess where this comes from, this is
IMHO fairly confusing for beginners (and kinda reminds me of the
infamous "infinite recursion at undefined position"-error).
The module-system determines the position of a declaration using the
`_file`-key: this is either `toString path` if `path` is e.g. a value
from `imports = [ ./foo.nix ]` or the file used as `NIXOS_CONFIG` in
`<nixpkgs/nixos>`.
However such a mechanism doesn't exist (yet) for inlined flake modules,
so I tried to implement this in a fairly basic way:
* For non-path declarations, the position of `modules` inside the
`flake.nix` which declares these modules is determined by doing
`unsafeGetAttrPos` on the `modules`-argument of `lib.nixosSystem`.
So the `flake.nix` from above would now raise the following
error-message:
$ nixos-rebuild build --flake .#foo -L
error: The option `services.wrong' does not exist. Definition values:
- In `/nix/store/4vi3nhqjyma73ygs4f93q38qjkhkaxw8-source/flake.nix': 2
Co-authored-by: Cole Helbling <cole.e.helbling@outlook.com>
Co-authored-by: Silvan Mosberger <github@infinisil.com>
Co-authored-by: Robert Hensing <robert@roberthensing.nl>
94 lines
3.0 KiB
Nix
94 lines
3.0 KiB
Nix
# Experimental flake interface to Nixpkgs.
|
|
# See https://github.com/NixOS/rfcs/pull/49 for details.
|
|
{
|
|
description = "A collection of packages for the Nix package manager";
|
|
|
|
outputs = { self }:
|
|
let
|
|
jobs = import ./pkgs/top-level/release.nix {
|
|
nixpkgs = self;
|
|
};
|
|
|
|
lib = import ./lib;
|
|
|
|
systems = [
|
|
"x86_64-linux"
|
|
"i686-linux"
|
|
"x86_64-darwin"
|
|
"aarch64-linux"
|
|
"armv6l-linux"
|
|
"armv7l-linux"
|
|
"aarch64-darwin"
|
|
];
|
|
|
|
forAllSystems = f: lib.genAttrs systems (system: f system);
|
|
|
|
in
|
|
{
|
|
lib = lib.extend (final: prev: {
|
|
nixosSystem = { modules, ... } @ args:
|
|
import ./nixos/lib/eval-config.nix (args // {
|
|
modules =
|
|
let
|
|
vmConfig = (import ./nixos/lib/eval-config.nix
|
|
(args // {
|
|
modules = modules ++ [ ./nixos/modules/virtualisation/qemu-vm.nix ];
|
|
})).config;
|
|
|
|
vmWithBootLoaderConfig = (import ./nixos/lib/eval-config.nix
|
|
(args // {
|
|
modules = modules ++ [
|
|
./nixos/modules/virtualisation/qemu-vm.nix
|
|
{ virtualisation.useBootLoader = true; }
|
|
({ config, ... }: {
|
|
virtualisation.useEFIBoot =
|
|
config.boot.loader.systemd-boot.enable ||
|
|
config.boot.loader.efi.canTouchEfiVariables;
|
|
})
|
|
];
|
|
})).config;
|
|
|
|
moduleDeclarationFile =
|
|
(builtins.unsafeGetAttrPos "modules" args).file;
|
|
|
|
# Add the invoking file as error message location for modules
|
|
# that don't have their own locations; presumably inline modules.
|
|
addModuleDeclarationFile =
|
|
m: {
|
|
_file = moduleDeclarationFile;
|
|
imports = [ m ];
|
|
};
|
|
|
|
in
|
|
map addModuleDeclarationFile modules ++ [
|
|
{
|
|
system.nixos.versionSuffix =
|
|
".${final.substring 0 8 (self.lastModifiedDate or self.lastModified or "19700101")}.${self.shortRev or "dirty"}";
|
|
system.nixos.revision = final.mkIf (self ? rev) self.rev;
|
|
|
|
system.build = {
|
|
vm = vmConfig.system.build.vm;
|
|
vmWithBootLoader = vmWithBootLoaderConfig.system.build.vm;
|
|
};
|
|
}
|
|
];
|
|
});
|
|
});
|
|
|
|
checks.x86_64-linux.tarball = jobs.tarball;
|
|
|
|
htmlDocs = {
|
|
nixpkgsManual = jobs.manual;
|
|
nixosManual = (import ./nixos/release-small.nix {
|
|
nixpkgs = self;
|
|
}).nixos.manual.x86_64-linux;
|
|
};
|
|
|
|
legacyPackages = forAllSystems (system: import ./. { inherit system; });
|
|
|
|
nixosModules = {
|
|
notDetected = import ./nixos/modules/installer/scan/not-detected.nix;
|
|
};
|
|
};
|
|
}
|