mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-14 01:33:10 +00:00
eb04659fc2
This was achieved using the following command:
sd 'wrapGAppsHook\b' wrapGAppsHook3 (rg -l 'wrapGAppsHook\b')
And then manually reverted the following changes:
- alias in top-level.nix
- function name in wrap-gapps-hook.sh
- comment in postFixup of at-spi2-core
- comment in gtk4
- comment in preFixup of 1password-gui/linux.nix
- comment in postFixup of qgis/unwrapped-ltr.nix and qgis/unwrapped.nix
- comment in postFixup of telegram-desktop
- comment in postFixup of fwupd
- buildCommand of mongodb-compass
- postFixup of xflux-gui
- comment in a patch in kdePackages.kde-gtk-config and plasma5Packages.kde-gtk-config
- description of programs.sway.wrapperFeatures.gtk NixOS option (manual rebuild)
83 lines
1.6 KiB
Nix
83 lines
1.6 KiB
Nix
{ lib
|
|
, fetchFromGitHub
|
|
, glib
|
|
, gobject-introspection
|
|
, gtk3
|
|
, keybinder3
|
|
, libwnck
|
|
, python3Packages
|
|
, wrapGAppsHook3
|
|
}:
|
|
|
|
python3Packages.buildPythonApplication rec {
|
|
pname = "dockbarx";
|
|
version = "1.0-beta2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "xuzhen";
|
|
repo = "dockbarx";
|
|
rev = version;
|
|
sha256 = "sha256-WMRTtprDHUbOOYVHshx7WpBlYshbiDjI12Rw3tQQuPI=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
glib.dev
|
|
gobject-introspection
|
|
python3Packages.polib
|
|
wrapGAppsHook3
|
|
];
|
|
|
|
buildInputs = [
|
|
gtk3
|
|
libwnck
|
|
keybinder3
|
|
];
|
|
|
|
propagatedBuildInputs = with python3Packages; [
|
|
dbus-python
|
|
pillow
|
|
pygobject3
|
|
pyxdg
|
|
xlib
|
|
];
|
|
|
|
# no tests
|
|
doCheck = false;
|
|
|
|
dontWrapGApps = true;
|
|
|
|
postPatch = ''
|
|
substituteInPlace setup.py \
|
|
--replace /usr/ "" \
|
|
--replace '"/", "usr", "share",' '"share",'
|
|
|
|
for f in \
|
|
dbx_preference \
|
|
dockbarx/applets.py \
|
|
dockbarx/dockbar.py \
|
|
dockbarx/iconfactory.py \
|
|
dockbarx/theme.py \
|
|
mate_panel_applet/dockbarx_mate_applet
|
|
do
|
|
substituteInPlace $f --replace /usr/share/ $out/share/
|
|
done
|
|
'';
|
|
|
|
postInstall = ''
|
|
glib-compile-schemas $out/share/glib-2.0/schemas
|
|
'';
|
|
|
|
# Arguments to be passed to `makeWrapper`, only used by buildPython*
|
|
preFixup = ''
|
|
makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/xuzhen/dockbarx";
|
|
description = "Lightweight taskbar/panel replacement which works as a stand-alone dock";
|
|
license = licenses.gpl3Only;
|
|
platforms = platforms.linux;
|
|
maintainers = [ maintainers.romildo ];
|
|
};
|
|
}
|