mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-24 16:03:23 +00:00
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
102 lines
3.0 KiB
Nix
102 lines
3.0 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
let
|
|
nncpCfgFile = "/run/nncp.hjson";
|
|
programCfg = config.programs.nncp;
|
|
settingsFormat = pkgs.formats.json { };
|
|
jsonCfgFile = settingsFormat.generate "nncp.json" programCfg.settings;
|
|
pkg = programCfg.package;
|
|
in {
|
|
options.programs.nncp = {
|
|
|
|
enable =
|
|
mkEnableOption "NNCP (Node to Node copy) utilities and configuration";
|
|
|
|
group = mkOption {
|
|
type = types.str;
|
|
default = "uucp";
|
|
description = lib.mdDoc ''
|
|
The group under which NNCP files shall be owned.
|
|
Any member of this group may access the secret keys
|
|
of this NNCP node.
|
|
'';
|
|
};
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.nncp;
|
|
defaultText = literalExpression "pkgs.nncp";
|
|
description = lib.mdDoc "The NNCP package to use system-wide.";
|
|
};
|
|
|
|
secrets = mkOption {
|
|
type = with types; listOf str;
|
|
example = [ "/run/keys/nncp.hjson" ];
|
|
description = ''
|
|
A list of paths to NNCP configuration files that should not be
|
|
in the Nix store. These files are layered on top of the values at
|
|
<xref linkend="opt-programs.nncp.settings"/>.
|
|
'';
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = settingsFormat.type;
|
|
description = ''
|
|
NNCP configuration, see
|
|
<link xlink:href="http://www.nncpgo.org/Configuration.html"/>.
|
|
At runtime these settings will be overlayed by the contents of
|
|
<xref linkend="opt-programs.nncp.secrets"/> into the file
|
|
<literal>${nncpCfgFile}</literal>. Node keypairs go in
|
|
<literal>secrets</literal>, do not specify them in
|
|
<literal>settings</literal> as they will be leaked into
|
|
<literal>/nix/store</literal>!
|
|
'';
|
|
default = { };
|
|
};
|
|
|
|
};
|
|
|
|
config = mkIf programCfg.enable {
|
|
|
|
environment = {
|
|
systemPackages = [ pkg ];
|
|
etc."nncp.hjson".source = nncpCfgFile;
|
|
};
|
|
|
|
programs.nncp.settings = {
|
|
spool = mkDefault "/var/spool/nncp";
|
|
log = mkDefault "/var/spool/nncp/log";
|
|
};
|
|
|
|
systemd.tmpfiles.rules = [
|
|
"d ${programCfg.settings.spool} 0770 root ${programCfg.group}"
|
|
"f ${programCfg.settings.log} 0770 root ${programCfg.group}"
|
|
];
|
|
|
|
systemd.services.nncp-config = {
|
|
path = [ pkg ];
|
|
description = "Generate NNCP configuration";
|
|
wantedBy = [ "basic.target" ];
|
|
serviceConfig.Type = "oneshot";
|
|
script = ''
|
|
umask u=rw
|
|
nncpCfgDir=$(mktemp --directory nncp.XXX)
|
|
for f in ${jsonCfgFile} ${toString config.programs.nncp.secrets}; do
|
|
tmpdir=$(mktemp --directory nncp.XXX)
|
|
nncp-cfgdir -cfg $f -dump $tmpdir
|
|
find $tmpdir -size 1c -delete
|
|
cp -a $tmpdir/* $nncpCfgDir/
|
|
rm -rf $tmpdir
|
|
done
|
|
nncp-cfgdir -load $nncpCfgDir > ${nncpCfgFile}
|
|
rm -rf $nncpCfgDir
|
|
chgrp ${programCfg.group} ${nncpCfgFile}
|
|
chmod g+r ${nncpCfgFile}
|
|
'';
|
|
};
|
|
};
|
|
|
|
meta.maintainers = with lib.maintainers; [ ehmry ];
|
|
}
|