mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-23 05:14:45 +00:00
720a248b44
Patch originated at Red Hat and was already applied for Fedora. ``` =================================== FAILURES =================================== __________________________ test_default_loop[pyloop] ___________________________ [XPASS(strict)] No idea why ClientRequest() is constructed out of loop but it calls `asyncio.get_event_loop()` ____________________ TestStreamReader.test_ctor_global_loop ____________________ [XPASS(strict)] No idea why ClientRequest() is constructed out of loop but it calls `asyncio.get_event_loop()` __________________________ test_set_loop_default_loop __________________________ [XPASS(strict)] No idea why _set_loop() is constructed out of loop but it calls `asyncio.get_event_loop()` ```
128 lines
2.9 KiB
Nix
128 lines
2.9 KiB
Nix
{ lib
|
||
, stdenv
|
||
, buildPythonPackage
|
||
, fetchPypi
|
||
, fetchpatch
|
||
, pythonOlder
|
||
# install_requires
|
||
, attrs
|
||
, charset-normalizer
|
||
, multidict
|
||
, async-timeout
|
||
, yarl
|
||
, frozenlist
|
||
, aiosignal
|
||
, aiodns
|
||
, brotli
|
||
, cchardet
|
||
, asynctest
|
||
, typing-extensions
|
||
, idna-ssl
|
||
# tests_require
|
||
, async_generator
|
||
, freezegun
|
||
, gunicorn
|
||
, pytest-mock
|
||
, pytestCheckHook
|
||
, re-assert
|
||
, trustme
|
||
}:
|
||
|
||
buildPythonPackage rec {
|
||
pname = "aiohttp";
|
||
version = "3.8.3";
|
||
format = "pyproject";
|
||
|
||
disabled = pythonOlder "3.6";
|
||
|
||
src = fetchPypi {
|
||
inherit pname version;
|
||
sha256 = "3828fb41b7203176b82fe5d699e0d845435f2374750a44b480ea6b930f6be269";
|
||
};
|
||
|
||
patches = [
|
||
(fetchpatch {
|
||
# https://github.com/aio-libs/aiohttp/pull/7178
|
||
url = "https://github.com/aio-libs/aiohttp/commit/5718879cdb6a98bf48810a994b78bc02abaf3e07.patch";
|
||
hash = "sha256-4UynkTZOzWzusQ2+MPZszhFA8I/PJNLeT/hHF/fASy8=";
|
||
})
|
||
];
|
||
|
||
postPatch = ''
|
||
sed -i '/--cov/d' setup.cfg
|
||
|
||
substituteInPlace setup.cfg \
|
||
--replace "charset-normalizer >=2.0, < 3.0" "charset-normalizer >=2.0, < 4.0"
|
||
'';
|
||
|
||
propagatedBuildInputs = [
|
||
attrs
|
||
charset-normalizer
|
||
multidict
|
||
async-timeout
|
||
yarl
|
||
typing-extensions
|
||
frozenlist
|
||
aiosignal
|
||
aiodns
|
||
brotli
|
||
cchardet
|
||
] ++ lib.optionals (pythonOlder "3.8") [
|
||
asynctest
|
||
typing-extensions
|
||
] ++ lib.optionals (pythonOlder "3.7") [
|
||
idna-ssl
|
||
];
|
||
|
||
nativeCheckInputs = [
|
||
async_generator
|
||
freezegun
|
||
gunicorn
|
||
pytest-mock
|
||
pytestCheckHook
|
||
re-assert
|
||
] ++ lib.optionals (!(stdenv.isDarwin && stdenv.isAarch64)) [
|
||
# Optional test dependency. Depends indirectly on pyopenssl, which is
|
||
# broken on aarch64-darwin.
|
||
trustme
|
||
];
|
||
|
||
disabledTests = [
|
||
# Disable tests that require network access
|
||
"test_client_session_timeout_zero"
|
||
"test_mark_formdata_as_processed"
|
||
"test_requote_redirect_url_default"
|
||
# Disable tests that trigger deprecation warnings in pytest
|
||
"test_async_with_session"
|
||
"test_session_close_awaitable"
|
||
"test_close_run_until_complete_not_deprecated"
|
||
] ++ lib.optionals stdenv.is32bit [
|
||
"test_cookiejar"
|
||
] ++ lib.optionals stdenv.isDarwin [
|
||
"test_addresses" # https://github.com/aio-libs/aiohttp/issues/3572, remove >= v4.0.0
|
||
"test_close"
|
||
];
|
||
|
||
disabledTestPaths = [
|
||
"test_proxy_functional.py" # FIXME package proxy.py
|
||
];
|
||
|
||
__darwinAllowLocalNetworking = true;
|
||
|
||
# aiohttp in current folder shadows installed version
|
||
# Probably because we run `python -m pytest` instead of `pytest` in the hook.
|
||
preCheck = ''
|
||
cd tests
|
||
'' + lib.optionalString stdenv.isDarwin ''
|
||
# Work around "OSError: AF_UNIX path too long"
|
||
export TMPDIR="/tmp"
|
||
'';
|
||
|
||
meta = with lib; {
|
||
description = "Asynchronous HTTP Client/Server for Python and asyncio";
|
||
license = licenses.asl20;
|
||
homepage = "https://github.com/aio-libs/aiohttp";
|
||
maintainers = with maintainers; [ dotlambda ];
|
||
};
|
||
}
|