mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-30 02:42:59 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
51 lines
1.7 KiB
Nix
51 lines
1.7 KiB
Nix
{ lib, stdenv, fetchgit, fetchpatch, autoreconfHook, pkg-config, gtk-doc, xkeyboard_config, libxml2, xorg, docbook_xsl
|
|
, glib, isocodes, gobject-introspection
|
|
, withDoc ? (stdenv.buildPlatform == stdenv.hostPlatform)
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "libxklavier";
|
|
version = "5.4";
|
|
|
|
src = fetchgit {
|
|
url = "https://gitlab.freedesktop.org/archived-projects/libxklavier.git";
|
|
rev = "${pname}-${version}";
|
|
sha256 = "1w1x5mrgly2ldiw3q2r6y620zgd89gk7n90ja46775lhaswxzv7a";
|
|
};
|
|
|
|
patches = [
|
|
./honor-XKB_CONFIG_ROOT.patch
|
|
] ++ lib.optionals stdenv.hostPlatform.isDarwin [
|
|
(fetchpatch {
|
|
url = "https://gitlab.freedesktop.org/archived-projects/libxklavier/-/commit/1387c21a788ec1ea203c8392ea1460fc29d83f70.patch";
|
|
sha256 = "sha256-fyWu7sVfDv/ozjhLSLCVsv+iNFawWgJqHUsQHHSkQn4=";
|
|
})
|
|
];
|
|
|
|
outputs = [ "out" "dev" ] ++ lib.optionals withDoc [ "devdoc" ];
|
|
|
|
# TODO: enable xmodmap support, needs xmodmap DB
|
|
propagatedBuildInputs = with xorg; [ libX11 libXi xkeyboard_config libxml2 libICE glib libxkbfile isocodes ];
|
|
|
|
nativeBuildInputs = [ autoreconfHook pkg-config gtk-doc docbook_xsl gobject-introspection ];
|
|
|
|
preAutoreconf = ''
|
|
export NOCONFIGURE=1
|
|
gtkdocize
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--with-xkb-base=${xkeyboard_config}/etc/X11/xkb"
|
|
"--with-xkb-bin-base=${xorg.xkbcomp}/bin"
|
|
"--disable-xmodmap-support"
|
|
"${if withDoc then "--enable-gtk-doc" else "--disable-gtk-doc"}"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "Library providing high-level API for X Keyboard Extension known as XKB";
|
|
homepage = "http://freedesktop.org/wiki/Software/LibXklavier";
|
|
license = licenses.lgpl2Plus;
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|