mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-06 04:53:27 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
52 lines
1.4 KiB
Nix
52 lines
1.4 KiB
Nix
{ lib, stdenv, fetchurl, makeDesktopItem, jdk8, copyDesktopItems, makeWrapper }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "jxplorer";
|
|
version = "3.3.1.2";
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/pegacat/jxplorer/releases/download/v${version}/jxplorer-${version}-project.tar.bz2";
|
|
hash = "sha256-/lWkavH51OqNFSLpgT+4WcQcfW3WvnnOkB03jB7bE/s=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
copyDesktopItems
|
|
makeWrapper
|
|
];
|
|
|
|
desktopItems = [
|
|
(makeDesktopItem {
|
|
name = "JXplorer";
|
|
exec = "jxplorer";
|
|
comment = "A Java Ldap Browser";
|
|
desktopName = "JXplorer";
|
|
genericName = "Java Ldap Browser";
|
|
icon = "jxplorer";
|
|
})
|
|
];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
install -d "$out/opt/jxplorer" "$out/bin" "$out/share/pixmaps"
|
|
cp -r ./. "$out/opt/jxplorer"
|
|
install -Dm644 images/JX128.png "$out/share/pixmaps/jxplorer.png"
|
|
runHook postInstall
|
|
'';
|
|
|
|
postFixup = ''
|
|
chmod +x $out/opt/jxplorer/jxplorer.sh
|
|
makeWrapper $out/opt/jxplorer/jxplorer.sh $out/bin/jxplorer \
|
|
--chdir $out/opt/jxplorer \
|
|
--set JAVA_HOME ${jdk8}
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Java Ldap Browser";
|
|
homepage = "https://sourceforge.net/projects/jxplorer/";
|
|
license = lib.licenses.caossl;
|
|
maintainers = with maintainers; [ benwbooth ];
|
|
platforms = platforms.linux;
|
|
mainProgram = "jxplorer";
|
|
};
|
|
}
|