mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-14 00:43:24 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
53 lines
1.2 KiB
Nix
53 lines
1.2 KiB
Nix
{ stdenv, lib, fetchFromGitHub, pkg-config, glib, libglibutil }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "libgbinder";
|
|
version = "1.1.40";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "mer-hybris";
|
|
repo = pname;
|
|
rev = version;
|
|
sha256 = "sha256-bv3UeL5xx28N/fSG1BeUSbbSvDaNgehpnx2OzIIaSXw=";
|
|
};
|
|
|
|
outputs = [ "out" "dev" ];
|
|
|
|
nativeBuildInputs = [
|
|
pkg-config
|
|
];
|
|
|
|
buildInputs = [
|
|
glib
|
|
libglibutil
|
|
];
|
|
|
|
postPatch = ''
|
|
# Fix pkg-config and ranlib names for cross-compilation
|
|
substituteInPlace Makefile \
|
|
--replace "pkg-config" "$PKG_CONFIG" \
|
|
--replace "ranlib" "$RANLIB"
|
|
'';
|
|
|
|
makeFlags = [
|
|
"LIBDIR=$(out)/lib"
|
|
"INSTALL_INCLUDE_DIR=$(dev)/include/gbinder"
|
|
"INSTALL_PKGCONFIG_DIR=$(dev)/lib/pkgconfig"
|
|
];
|
|
|
|
installTargets = [ "install" "install-dev" ];
|
|
|
|
postInstall = ''
|
|
sed -i -e "s@includedir=/usr@includedir=$dev@g" $dev/lib/pkgconfig/$pname.pc
|
|
sed -i -e "s@Cflags: @Cflags: $($PKG_CONFIG --cflags libglibutil) @g" $dev/lib/pkgconfig/$pname.pc
|
|
'';
|
|
|
|
meta = {
|
|
description = "GLib-style interface to binder";
|
|
homepage = "https://github.com/mer-hybris/libgbinder";
|
|
license = lib.licenses.bsd3;
|
|
platforms = lib.platforms.linux;
|
|
maintainers = with lib.maintainers; [ ];
|
|
};
|
|
}
|