mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-26 15:44:20 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
60 lines
1.3 KiB
Nix
60 lines
1.3 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, cmake
|
|
, cmocka
|
|
|
|
# for passthru.tests
|
|
, libfido2
|
|
, mysql80
|
|
, openssh
|
|
, systemd
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "libcbor";
|
|
version = "0.11.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "PJK";
|
|
repo = "libcbor";
|
|
rev = "v${finalAttrs.version}";
|
|
hash = "sha256-N1xYkZw/6lX/nX/TE6/pVuEFgSyDiUJ50msK42NrKwI=";
|
|
};
|
|
|
|
outputs = [ "out" "dev" ];
|
|
|
|
strictDeps = true;
|
|
nativeBuildInputs = [ cmake ];
|
|
|
|
buildInputs = [
|
|
cmocka # cmake expects cmocka module
|
|
];
|
|
|
|
cmakeFlags = lib.optional finalAttrs.finalPackage.doCheck "-DWITH_TESTS=ON"
|
|
++ lib.optional (!stdenv.hostPlatform.isStatic) "-DBUILD_SHARED_LIBS=ON";
|
|
|
|
# Tests are restricted while pkgsStatic.cmocka is broken. Tracked at:
|
|
# https://github.com/NixOS/nixpkgs/issues/213623
|
|
doCheck = !stdenv.hostPlatform.isStatic
|
|
&& stdenv.hostPlatform == stdenv.buildPlatform;
|
|
|
|
nativeCheckInputs = [ cmocka ];
|
|
|
|
passthru.tests = {
|
|
inherit libfido2 mysql80;
|
|
openssh = (openssh.override { withFIDO = true; });
|
|
systemd = (systemd.override {
|
|
withFido2 = true;
|
|
withCryptsetup = true;
|
|
});
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "CBOR protocol implementation for C and others";
|
|
homepage = "https://github.com/PJK/libcbor";
|
|
license = licenses.mit;
|
|
maintainers = [ ];
|
|
};
|
|
})
|