mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-26 23:54:01 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
47 lines
1.4 KiB
Nix
47 lines
1.4 KiB
Nix
{ lib, stdenv, fetchFromGitHub, pkg-config, glib, libpulseaudio }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "libcardiacarrest";
|
|
version = "12.2.8"; # <PA API version>.<version>
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "oxij";
|
|
repo = "libcardiacarrest";
|
|
rev = "d89639f5b2d298cf74af26880f5ebf50e645166d";
|
|
sha256 = "0vrigwcw3g8zknqyznv6y3437ahn1w00gv3d303smmygr0p8bd94";
|
|
};
|
|
|
|
outputs = [ "out" "dev" ];
|
|
|
|
nativeBuildInputs = [ pkg-config ];
|
|
|
|
buildInputs = [ glib ];
|
|
|
|
makeFlags = [ "PREFIX=$(out)" ];
|
|
|
|
postInstall = ''
|
|
moveToOutput $out/include $dev
|
|
moveToOutput $out/lib/pkgconfig $dev
|
|
moveToOutput $out/lib/cmake $dev
|
|
'';
|
|
|
|
meta = with lib; src.meta // {
|
|
description = "Trivial implementation of libpulse PulseAudio library API";
|
|
longDescription = ''
|
|
libcardiacarrest is a trivial implementation of libpulse
|
|
PulseAudio library API that unconditionally (but gracefully)
|
|
fails to connect to the PulseAudio daemon and does nothing else.
|
|
|
|
apulse and pressureaudio (which uses apulse internally) are an
|
|
inspiration for this but unlike those two projects
|
|
libcardiacarrest is not an emulation layer, all it does is it
|
|
gracefully fails to provide the requested PulseAudio service
|
|
hoping the application would try something else (e.g. ALSA or
|
|
JACK).
|
|
'';
|
|
license = libpulseaudio.meta.license; # "same as PA headers"
|
|
maintainers = [ maintainers.oxij ]; # also the author
|
|
};
|
|
|
|
}
|