mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-29 00:53:57 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
139 lines
3.5 KiB
Nix
139 lines
3.5 KiB
Nix
{
|
|
lib,
|
|
php,
|
|
runCommand,
|
|
}:
|
|
|
|
let
|
|
runTest =
|
|
name: body:
|
|
runCommand name { } ''
|
|
testFailed=
|
|
checking() {
|
|
echo -n "Checking $1... " > /dev/stderr
|
|
}
|
|
ok() {
|
|
echo ok > /dev/stderr
|
|
}
|
|
nok() {
|
|
echo fail > /dev/stderr
|
|
testFailed=1
|
|
}
|
|
|
|
${body}
|
|
|
|
if test -n "$testFailed"; then
|
|
exit 1
|
|
fi
|
|
|
|
touch $out
|
|
'';
|
|
|
|
check = cond: if cond then "ok" else "nok";
|
|
in
|
|
{
|
|
withExtensions-enables-previously-disabled-extensions = runTest "php-test-withExtensions-enables-previously-disabled-extensions" ''
|
|
php="${php}"
|
|
|
|
checking "that imagick is not present by default"
|
|
$php/bin/php -r 'exit(extension_loaded("imagick") ? 1 : 0);' && ok || nok
|
|
|
|
phpWithImagick="${php.withExtensions ({ all, ... }: [ all.imagick ])}"
|
|
checking "that imagick extension is present when enabled"
|
|
$phpWithImagick/bin/php -r 'exit(extension_loaded("imagick") ? 0 : 1);' && ok || nok
|
|
'';
|
|
|
|
overrideAttrs-preserves-enabled-extensions =
|
|
let
|
|
customPhp = (php.withExtensions ({ all, ... }: [ all.imagick ])).overrideAttrs (attrs: {
|
|
postInstall =
|
|
attrs.postInstall or ""
|
|
+ ''
|
|
touch "$out/oApee-was-here"
|
|
'';
|
|
});
|
|
in
|
|
runTest "php-test-overrideAttrs-preserves-enabled-extensions" ''
|
|
php="${customPhp}"
|
|
phpUnwrapped="${customPhp.unwrapped}"
|
|
|
|
checking "if overrides took hold"
|
|
test -f "$phpUnwrapped/oApee-was-here" && ok || nok
|
|
|
|
checking "if imagick extension is still present"
|
|
$php/bin/php -r 'exit(extension_loaded("imagick") ? 0 : 1);' && ok || nok
|
|
|
|
checking "if imagick extension is linked against the overridden PHP"
|
|
echo $php
|
|
$php/bin/php -r 'exit(extension_loaded("imagick") ? 0 : 1);' && ok || nok
|
|
'';
|
|
|
|
unwrapped-overrideAttrs-stacks =
|
|
let
|
|
customPhp = lib.pipe php.unwrapped [
|
|
(
|
|
pkg:
|
|
pkg.overrideAttrs (attrs: {
|
|
postInstall =
|
|
attrs.postInstall or ""
|
|
+ ''
|
|
touch "$out/oAs-first"
|
|
'';
|
|
})
|
|
)
|
|
|
|
(
|
|
pkg:
|
|
pkg.overrideAttrs (attrs: {
|
|
postInstall =
|
|
attrs.postInstall or ""
|
|
+ ''
|
|
touch "$out/oAs-second"
|
|
'';
|
|
})
|
|
)
|
|
];
|
|
in
|
|
runTest "php-test-unwrapped-overrideAttrs-stacks" ''
|
|
checking "if first override remained"
|
|
${check (builtins.match ".*oAs-first.*" customPhp.postInstall != null)}
|
|
|
|
checking "if second override is there"
|
|
${check (builtins.match ".*oAs-second.*" customPhp.postInstall != null)}
|
|
'';
|
|
|
|
wrapped-overrideAttrs-stacks =
|
|
let
|
|
customPhp = lib.pipe php [
|
|
(
|
|
pkg:
|
|
pkg.overrideAttrs (attrs: {
|
|
postInstall =
|
|
attrs.postInstall or ""
|
|
+ ''
|
|
touch "$out/oAs-first"
|
|
'';
|
|
})
|
|
)
|
|
|
|
(
|
|
pkg:
|
|
pkg.overrideAttrs (attrs: {
|
|
postInstall =
|
|
attrs.postInstall or ""
|
|
+ ''
|
|
touch "$out/oAs-second"
|
|
'';
|
|
})
|
|
)
|
|
];
|
|
in
|
|
runTest "php-test-wrapped-overrideAttrs-stacks" ''
|
|
checking "if first override remained"
|
|
${check (builtins.match ".*oAs-first.*" customPhp.unwrapped.postInstall != null)}
|
|
|
|
checking "if second override is there"
|
|
${check (builtins.match ".*oAs-second.*" customPhp.unwrapped.postInstall != null)}
|
|
'';
|
|
}
|