mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-27 17:33:09 +00:00
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
76 lines
2.0 KiB
Nix
76 lines
2.0 KiB
Nix
{ config, lib, pkgs, utils, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
xcfg = config.services.xserver;
|
|
cfg = xcfg.desktopManager.lxqt;
|
|
|
|
in
|
|
|
|
{
|
|
meta = {
|
|
maintainers = teams.lxqt.members;
|
|
};
|
|
|
|
options = {
|
|
|
|
services.xserver.desktopManager.lxqt.enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc "Enable the LXQt desktop manager";
|
|
};
|
|
|
|
environment.lxqt.excludePackages = mkOption {
|
|
default = [];
|
|
example = literalExpression "[ pkgs.lxqt.qterminal ]";
|
|
type = types.listOf types.package;
|
|
description = lib.mdDoc "Which LXQt packages to exclude from the default environment";
|
|
};
|
|
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
services.xserver.desktopManager.session = singleton {
|
|
name = "lxqt";
|
|
bgSupport = true;
|
|
start = ''
|
|
# Upstream installs default configuration files in
|
|
# $prefix/share/lxqt instead of $prefix/etc/xdg, (arguably)
|
|
# giving distributors freedom to ship custom default
|
|
# configuration files more easily. In order to let the session
|
|
# manager find them the share subdirectory is added to the
|
|
# XDG_CONFIG_DIRS environment variable.
|
|
#
|
|
# For an explanation see
|
|
# https://github.com/lxqt/lxqt/issues/1521#issuecomment-405097453
|
|
#
|
|
export XDG_CONFIG_DIRS=$XDG_CONFIG_DIRS''${XDG_CONFIG_DIRS:+:}${config.system.path}/share
|
|
|
|
exec ${pkgs.lxqt.lxqt-session}/bin/startlxqt
|
|
'';
|
|
};
|
|
|
|
environment.systemPackages =
|
|
pkgs.lxqt.preRequisitePackages ++
|
|
pkgs.lxqt.corePackages ++
|
|
(utils.removePackagesByName
|
|
pkgs.lxqt.optionalPackages
|
|
config.environment.lxqt.excludePackages);
|
|
|
|
# Link some extra directories in /run/current-system/software/share
|
|
environment.pathsToLink = [ "/share" ];
|
|
|
|
# virtual file systems support for PCManFM-QT
|
|
services.gvfs.enable = true;
|
|
|
|
services.upower.enable = config.powerManagement.enable;
|
|
|
|
services.xserver.libinput.enable = mkDefault true;
|
|
|
|
xdg.portal.lxqt.enable = true;
|
|
};
|
|
|
|
}
|