mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-18 03:34:58 +00:00
c092a502df
Only packages I'm not able to maintain anymore as of today. Mostly because I'm haven't been using them in a while.
125 lines
3.3 KiB
Nix
125 lines
3.3 KiB
Nix
{ stdenv
|
|
, lib
|
|
, fetchurl
|
|
, autoPatchelfHook
|
|
, unzip
|
|
, makeWrapper
|
|
, setJavaClassPath
|
|
, zulu
|
|
# minimum dependencies
|
|
, alsa-lib
|
|
, fontconfig
|
|
, freetype
|
|
, zlib
|
|
, xorg
|
|
# runtime dependencies
|
|
, cups
|
|
# runtime dependencies for GTK+ Look and Feel
|
|
, gtkSupport ? stdenv.isLinux
|
|
, cairo
|
|
, glib
|
|
, gtk3
|
|
}:
|
|
|
|
let
|
|
version = "11.52.13";
|
|
openjdk = "11.0.13";
|
|
|
|
sha256_x64_linux = "77a126669b26b3a89e0117b0f28cddfcd24fcd7699b2c1d35f921487148b9a9f";
|
|
sha256_x64_darwin = "a96f9f859350f977319ebb5c2a999c182ab6b99b24c60e19d97c54367868a63e";
|
|
sha256_aarch64_darwin = "dmzfergSUVz39T30PT/6ZtT8JNqv5lzdX7zUsXsFGJg=";
|
|
|
|
platform = if stdenv.isDarwin then "macosx" else "linux";
|
|
hash = if stdenv.isAarch64 && stdenv.isDarwin then sha256_aarch64_darwin else if stdenv.isDarwin then sha256_x64_darwin else sha256_x64_linux;
|
|
extension = if stdenv.isDarwin then "zip" else "tar.gz";
|
|
architecture = if stdenv.isAarch64 then "aarch64" else "x64";
|
|
|
|
runtimeDependencies = [
|
|
cups
|
|
] ++ lib.optionals gtkSupport [
|
|
cairo glib gtk3
|
|
];
|
|
runtimeLibraryPath = lib.makeLibraryPath runtimeDependencies;
|
|
|
|
in stdenv.mkDerivation {
|
|
inherit version openjdk platform hash extension;
|
|
|
|
pname = "zulu";
|
|
|
|
src = fetchurl {
|
|
url = "https://cdn.azul.com/zulu/bin/zulu${version}-ca-jdk${openjdk}-${platform}_${architecture}.${extension}";
|
|
sha256 = hash;
|
|
};
|
|
|
|
buildInputs = lib.optionals stdenv.isLinux [
|
|
alsa-lib # libasound.so wanted by lib/libjsound.so
|
|
fontconfig
|
|
freetype
|
|
stdenv.cc.cc # libstdc++.so.6
|
|
xorg.libX11
|
|
xorg.libXext
|
|
xorg.libXi
|
|
xorg.libXrender
|
|
xorg.libXtst
|
|
zlib
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
makeWrapper
|
|
] ++ lib.optionals stdenv.isLinux [
|
|
autoPatchelfHook
|
|
] ++ lib.optionals stdenv.isDarwin [
|
|
unzip
|
|
];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out
|
|
cp -r ./* "$out/"
|
|
'' + lib.optionalString stdenv.isLinux ''
|
|
# jni.h expects jni_md.h to be in the header search path.
|
|
ln -s $out/include/linux/*_md.h $out/include/
|
|
'' + ''
|
|
mkdir -p $out/nix-support
|
|
printWords ${setJavaClassPath} > $out/nix-support/propagated-build-inputs
|
|
|
|
# Set JAVA_HOME automatically.
|
|
cat <<EOF >> $out/nix-support/setup-hook
|
|
if [ -z "\''${JAVA_HOME-}" ]; then export JAVA_HOME=$out; fi
|
|
EOF
|
|
'' + lib.optionalString stdenv.isLinux ''
|
|
# We cannot use -exec since wrapProgram is a function but not a command.
|
|
#
|
|
# jspawnhelper is executed from JVM, so it doesn't need to wrap it, and it
|
|
# breaks building OpenJDK (#114495).
|
|
for bin in $( find "$out" -executable -type f -not -name jspawnhelper ); do
|
|
wrapProgram "$bin" --prefix LD_LIBRARY_PATH : "${runtimeLibraryPath}"
|
|
done
|
|
'' + ''
|
|
runHook postInstall
|
|
'';
|
|
|
|
preFixup = ''
|
|
find "$out" -name libfontmanager.so -exec \
|
|
patchelf --add-needed libfontconfig.so {} \;
|
|
'';
|
|
|
|
passthru = {
|
|
home = zulu;
|
|
};
|
|
|
|
meta = with lib; {
|
|
homepage = "https://www.azul.com/products/zulu/";
|
|
license = licenses.gpl2;
|
|
description = "Certified builds of OpenJDK";
|
|
longDescription = ''
|
|
Certified builds of OpenJDK that can be deployed across multiple
|
|
operating systems, containers, hypervisors and Cloud platforms.
|
|
'';
|
|
maintainers = with maintainers; [ ];
|
|
platforms = [ "x86_64-linux" "x86_64-darwin" "aarch64-darwin" ];
|
|
mainProgram = "java";
|
|
};
|
|
}
|