mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-08 22:14:34 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
56 lines
1.8 KiB
Nix
56 lines
1.8 KiB
Nix
{ config, lib, stdenv, fetchurl
|
|
, bison, flex
|
|
, sysfsutils, kmod, udev
|
|
, firmware ? config.pcmciaUtils.firmware or [] # Special pcmcia cards.
|
|
, configOpts ? config.pcmciaUtils.config or null # Special hardware (map memory & port & irq)
|
|
}: # used to generate postInstall script.
|
|
|
|
# FIXME: should add an option to choose between hotplug and udev.
|
|
stdenv.mkDerivation rec {
|
|
pname = "pcmciautils";
|
|
version = "018";
|
|
|
|
src = fetchurl {
|
|
url = "https://kernel.org/pub/linux/utils/kernel/pcmcia/pcmciautils-${version}.tar.gz";
|
|
sha256 = "0sfm3w2n73kl5w7gb1m6q8gy5k4rgwvzz79n6yhs9w3sag3ix8sk";
|
|
};
|
|
|
|
buildInputs = [udev bison sysfsutils kmod flex];
|
|
|
|
patchPhase = ''
|
|
sed -i "
|
|
s,/sbin/modprobe,${kmod}&,;
|
|
s,/lib/udev/,$out/sbin/,;
|
|
" udev/* # fix-color */
|
|
sed -i "
|
|
s,/lib/firmware,$out&,;
|
|
s,/etc/pcmcia,$out&,;
|
|
" src/{startup.c,pcmcia-check-broken-cis.c} # fix-color */
|
|
''
|
|
+ (lib.optionalString (firmware == []) ''sed -i "s,STARTUP = true,STARTUP = false," Makefile'')
|
|
+ (lib.optionalString (configOpts != null) "ln -sf ${configOpts} ./config/config.opts")
|
|
;
|
|
|
|
makeFlags = [ "LEX=flex" ];
|
|
installFlags = [ "INSTALL=install" "DESTDIR=${placeholder "out"}" ];
|
|
postInstall =
|
|
lib.concatMapStrings (path: ''
|
|
for f in : $(find ${path} -type f); do
|
|
test "$f" == ":" && continue;
|
|
mkdir -p $(dirname $out/lib/firmware/$\{f#${path}});
|
|
ln -s $f $out/lib/firmware/$\{f#${path}};
|
|
done;
|
|
'') firmware;
|
|
|
|
meta = {
|
|
homepage = "https://www.kernel.org/pub/linux/utils/kernel/pcmcia/";
|
|
longDescription = "
|
|
PCMCIAutils contains the initialization tools necessary to allow
|
|
the PCMCIA subsystem to behave (almost) as every other
|
|
hotpluggable bus system.
|
|
";
|
|
license = lib.licenses.gpl2Only;
|
|
platforms = lib.platforms.linux;
|
|
};
|
|
}
|