mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-19 12:14:10 +00:00
55 lines
1.8 KiB
Nix
55 lines
1.8 KiB
Nix
{ lib, stdenv, fetchurl, fetchsvn, makeWrapper, unzip, jre, libXxf86vm
|
|
, extraJavaOpts ? "-Djosm.restart=true -Djava.net.useSystemProxies=true"
|
|
}:
|
|
let
|
|
pname = "josm";
|
|
version = "18700";
|
|
srcs = {
|
|
jar = fetchurl {
|
|
url = "https://josm.openstreetmap.de/download/josm-snapshot-${version}.jar";
|
|
hash = "sha256-rJw38pOHi+OIjIKgglU0Y2Tlc/b8K9f04ru2IH0CUJ0=";
|
|
};
|
|
macosx = fetchurl {
|
|
url = "https://josm.openstreetmap.de/download/macosx/josm-macos-${version}-java17.zip";
|
|
hash = "sha256-RTRe2GZz5B9QEYF04PiKtKJkWu0Em5WBqK4dVQVHK0g=";
|
|
};
|
|
pkg = fetchsvn {
|
|
url = "https://josm.openstreetmap.de/svn/trunk/native/linux/tested";
|
|
rev = version;
|
|
sha256 = "sha256-/zdOaiyuvSwdVZcnw0ghDj2I+YKpFLc12fjZUMtRtVg=";
|
|
};
|
|
};
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
inherit pname version;
|
|
|
|
dontUnpack = true;
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
buildInputs = lib.optionals (!stdenv.isDarwin) [ jre ];
|
|
|
|
installPhase =
|
|
if stdenv.isDarwin then ''
|
|
mkdir -p $out/Applications
|
|
${unzip}/bin/unzip ${srcs.macosx} 'JOSM.app/*' -d $out/Applications
|
|
'' else ''
|
|
install -Dm644 ${srcs.jar} $out/share/josm/josm.jar
|
|
cp -R ${srcs.pkg}/usr/share $out
|
|
|
|
# Add libXxf86vm to path because it is needed by at least Kendzi3D plugin
|
|
makeWrapper ${jre}/bin/java $out/bin/josm \
|
|
--add-flags "${extraJavaOpts} -jar $out/share/josm/josm.jar" \
|
|
--prefix LD_LIBRARY_PATH ":" '${libXxf86vm}/lib'
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "An extensible editor for OpenStreetMap";
|
|
homepage = "https://josm.openstreetmap.de/";
|
|
changelog = "https://josm.openstreetmap.de/wiki/Changelog";
|
|
sourceProvenance = with sourceTypes; [ binaryBytecode ];
|
|
license = licenses.gpl2Plus;
|
|
maintainers = with maintainers; [ rycee sikmir ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|