mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-04 20:13:21 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
68 lines
2.1 KiB
Nix
68 lines
2.1 KiB
Nix
{ lib, fetchgit, SDL, stdenv, libogg, libvorbis, libmad, xdelta }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "uhexen2";
|
|
version = "1.5.9";
|
|
|
|
src = fetchgit {
|
|
url = "https://git.code.sf.net/p/uhexen2/uhexen2";
|
|
sha256 = "0crdihbnb92awkikn15mzdpkj1x9s34xixf1r7fxxf762m60niks";
|
|
rev = "4ef664bc41e3998b0d2a55ff1166dadf34c936be";
|
|
};
|
|
|
|
buildInputs = [ SDL libogg libvorbis libmad xdelta ];
|
|
|
|
preBuild = ''
|
|
makeFiles=(
|
|
"engine/hexen2 glh2"
|
|
"engine/hexen2 clean"
|
|
"engine/hexen2 h2"
|
|
"engine/hexen2/server"
|
|
"engine/hexenworld/client glhw"
|
|
"engine/hexenworld/client clean"
|
|
"engine/hexenworld/client hw"
|
|
"engine/hexenworld/server"
|
|
"h2patch"
|
|
)
|
|
'';
|
|
|
|
buildPhase = ''
|
|
runHook preBuild
|
|
for makefile in "''${makeFiles[@]}"; do
|
|
local flagsArray=(
|
|
-j$NIX_BUILD_CORES
|
|
SHELL=$SHELL
|
|
$makeFlags "''${makeFlagsArray[@]}"
|
|
$buildFlags "''${buildFlagsArray[@]}"
|
|
)
|
|
echoCmd 'build flags' ""''${flagsArray[@]}""
|
|
make -C $makefile ""''${flagsArray[@]}""
|
|
unset flagsArray
|
|
done
|
|
runHook postBuild
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
install -Dm755 engine/hexen2/{glhexen2,hexen2,server/h2ded} -t $out/bin
|
|
install -Dm755 engine/hexenworld/{client/glhwcl,client/hwcl,server/hwsv} -t $out/bin
|
|
install -Dm755 h2patch/h2patch -t $out/bin
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
broken = stdenv.hostPlatform.isDarwin;
|
|
description = "Cross-platform port of Hexen II game";
|
|
longDescription = ''
|
|
Hammer of Thyrion (uHexen2) is a cross-platform port of Raven Software's Hexen II source.
|
|
It is based on an older linux port, Anvil of Thyrion.
|
|
HoT includes countless bug fixes, improved music, sound and video modes, opengl improvements,
|
|
support for many operating systems and architectures, and documentation among many others.
|
|
'';
|
|
homepage = "https://uhexen2.sourceforge.net/";
|
|
license = licenses.gpl2Plus;
|
|
maintainers = with maintainers; [ xdhampus ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|