mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-26 07:34:11 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
62 lines
1.5 KiB
Nix
62 lines
1.5 KiB
Nix
{
|
|
lib,
|
|
buildGoModule,
|
|
fetchFromGitHub,
|
|
installShellFiles,
|
|
testers,
|
|
clusterctl,
|
|
}:
|
|
|
|
buildGoModule rec {
|
|
pname = "clusterctl";
|
|
version = "1.8.5";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "kubernetes-sigs";
|
|
repo = "cluster-api";
|
|
rev = "v${version}";
|
|
hash = "sha256-Twh8wIXc1bLljTUCxMV/b5qP65FG14hheoMFTnGrO/c=";
|
|
};
|
|
|
|
vendorHash = "sha256-0VVaD1vGIGezgkVCvIhNHmZqVFxFu4UcUUh0wuX2viw=";
|
|
|
|
subPackages = [ "cmd/clusterctl" ];
|
|
|
|
nativeBuildInputs = [ installShellFiles ];
|
|
|
|
ldflags =
|
|
let
|
|
t = "sigs.k8s.io/cluster-api/version";
|
|
in
|
|
[
|
|
"-X ${t}.gitMajor=${lib.versions.major version}"
|
|
"-X ${t}.gitMinor=${lib.versions.minor version}"
|
|
"-X ${t}.gitVersion=v${version}"
|
|
];
|
|
|
|
postInstall = ''
|
|
# errors attempting to write config to read-only $HOME
|
|
export HOME=$TMPDIR
|
|
|
|
installShellCompletion --cmd clusterctl \
|
|
--bash <($out/bin/clusterctl completion bash) \
|
|
--fish <($out/bin/clusterctl completion fish) \
|
|
--zsh <($out/bin/clusterctl completion zsh)
|
|
'';
|
|
|
|
passthru.tests.version = testers.testVersion {
|
|
package = clusterctl;
|
|
command = "HOME=$TMPDIR clusterctl version";
|
|
version = "v${version}";
|
|
};
|
|
|
|
meta = {
|
|
changelog = "https://github.com/kubernetes-sigs/cluster-api/releases/tag/${src.rev}";
|
|
description = "Kubernetes cluster API tool";
|
|
mainProgram = "clusterctl";
|
|
homepage = "https://cluster-api.sigs.k8s.io/";
|
|
license = lib.licenses.asl20;
|
|
maintainers = with lib.maintainers; [ qjoly ];
|
|
};
|
|
}
|