mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-06 21:13:40 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
48 lines
1.6 KiB
Nix
48 lines
1.6 KiB
Nix
# given a package with a $name.desktop file, makes a copy
|
|
# as autostart item.
|
|
|
|
{ stdenv, lib }:
|
|
{
|
|
name, # name of the desktop file (without .desktop)
|
|
package, # package where the desktop file resides in
|
|
srcPrefix ? "", # additional prefix that the desktop file may have in the 'package'
|
|
after ? null,
|
|
condition ? null,
|
|
phase ? "2",
|
|
prependExtraArgs ? [ ],
|
|
appendExtraArgs ? [ ],
|
|
}:
|
|
|
|
# the builder requires that
|
|
# $package/share/applications/$name.desktop
|
|
# exists as file.
|
|
|
|
stdenv.mkDerivation {
|
|
name = "autostart-${name}";
|
|
priority = 5;
|
|
|
|
buildCommand =
|
|
let
|
|
escapeArgs = args: lib.escapeRegex (lib.escapeShellArgs args);
|
|
prependArgs = lib.optionalString (prependExtraArgs != [ ]) "${escapeArgs prependExtraArgs} ";
|
|
appendArgs = lib.optionalString (appendExtraArgs != [ ]) " ${escapeArgs appendExtraArgs}";
|
|
in
|
|
''
|
|
mkdir -p $out/etc/xdg/autostart
|
|
target=${name}.desktop
|
|
cp ${package}/share/applications/${srcPrefix}${name}.desktop $target
|
|
${lib.optionalString (prependExtraArgs != [ ] || appendExtraArgs != [ ]) ''
|
|
sed -i -r "s/(Exec=)([^ \n]*) *(.*)/\1\2 ${prependArgs}\3${appendArgs}/" $target
|
|
''}
|
|
chmod +rw $target
|
|
echo "X-KDE-autostart-phase=${phase}" >> $target
|
|
${lib.optionalString (after != null) ''echo "${after}" >> $target''}
|
|
${lib.optionalString (condition != null) ''echo "${condition}" >> $target''}
|
|
cp $target $out/etc/xdg/autostart
|
|
'';
|
|
|
|
# this will automatically put 'package' in the environment when you
|
|
# put its startup item in there.
|
|
propagatedBuildInputs = [ package ];
|
|
}
|