mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-07 21:43:32 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
53 lines
974 B
Nix
53 lines
974 B
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromSourcehut
|
|
, writeText
|
|
, libinput
|
|
, libX11
|
|
, wayland
|
|
, conf ? null
|
|
, patches ? [ ]
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "lisgd";
|
|
version = "0.4.0";
|
|
|
|
src = fetchFromSourcehut {
|
|
owner = "~mil";
|
|
repo = "lisgd";
|
|
rev = version;
|
|
hash = "sha256-ljRZpBo4lW2cYZYxKKMrXanE0YaHSFwcdyECK0czdWY=";
|
|
};
|
|
|
|
inherit patches;
|
|
|
|
postPatch = let
|
|
configFile = if lib.isDerivation conf || lib.isPath conf then
|
|
conf
|
|
else
|
|
writeText "config.def.h" conf;
|
|
in lib.optionalString (conf != null) ''
|
|
cp ${configFile} config.def.h
|
|
'';
|
|
|
|
buildInputs = [
|
|
libinput
|
|
libX11
|
|
wayland
|
|
];
|
|
|
|
makeFlags = [
|
|
"PREFIX=${placeholder "out"}"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "Bind gestures via libinput touch events";
|
|
mainProgram = "lisgd";
|
|
homepage = "https://git.sr.ht/~mil/lisgd";
|
|
license = licenses.mit;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ dotlambda ];
|
|
};
|
|
}
|