mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-27 16:15:05 +00:00
4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
63 lines
1.8 KiB
Nix
63 lines
1.8 KiB
Nix
{ lib, stdenv, fetchurl, apfel, apfelgrid, applgrid, blas, gfortran, lhapdf, lapack, libyaml, lynx
|
|
, mela, root5, qcdnum, which, libtirpc
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "xfitter";
|
|
version = "2.0.1";
|
|
|
|
src = fetchurl {
|
|
name = "${pname}-${version}.tgz";
|
|
url = "https://www.xfitter.org/xFitter/xFitter/DownloadPage?action=AttachFile&do=get&target=${pname}-${version}.tgz";
|
|
sha256 = "0kmgc67nw5flp92yw5x6l2vsnhwsfi5z2a20404anisdgdjs8zc6";
|
|
};
|
|
|
|
patches = [
|
|
./undefined_behavior.patch
|
|
];
|
|
|
|
# patch needs to updated due to version bump
|
|
#CXXFLAGS = "-Werror=return-type";
|
|
|
|
preConfigure =
|
|
# Fix F77LD to workaround for a following build error:
|
|
#
|
|
# gfortran: error: unrecognized command line option '-stdlib=libc++'
|
|
#
|
|
stdenv.lib.optionalString stdenv.isDarwin ''
|
|
substituteInPlace src/Makefile.in \
|
|
--replace "F77LD = \$(F77)" "F77LD = \$(CXXLD)" \
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--enable-apfel"
|
|
"--enable-apfelgrid"
|
|
"--enable-applgrid"
|
|
"--enable-mela"
|
|
"--enable-lhapdf"
|
|
];
|
|
|
|
nativeBuildInputs = [ gfortran which ];
|
|
buildInputs =
|
|
[ apfel apfelgrid applgrid blas lhapdf lapack mela root5 qcdnum libtirpc ]
|
|
# pdf2yaml requires fmemopen and open_memstream which are not readily available on Darwin
|
|
++ stdenv.lib.optional (!stdenv.isDarwin) libyaml
|
|
;
|
|
propagatedBuildInputs = [ lynx ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
hardeningDisable = [ "format" ];
|
|
|
|
NIX_CFLAGS_COMPILE = [ "-I${libtirpc.dev}/include/tirpc" ];
|
|
NIX_LDFLAGS = [ "-ltirpc" ];
|
|
|
|
meta = with lib; {
|
|
description = "The xFitter project is an open source QCD fit framework ready to extract PDFs and assess the impact of new data";
|
|
license = licenses.gpl3;
|
|
homepage = "https://www.xfitter.org/xFitter";
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ veprbl ];
|
|
};
|
|
}
|