mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-03 19:43:30 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
37 lines
1.1 KiB
Nix
37 lines
1.1 KiB
Nix
{ ctags, fetchurl, lib, libressl, ncurses, pkg-config, stdenv }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "catgirl";
|
|
version = "2.2a";
|
|
|
|
src = fetchurl {
|
|
url = "https://git.causal.agency/catgirl/snapshot/${pname}-${version}.tar.gz";
|
|
hash = "sha256-xtdgqu4TTgUlht73qRA1Q/coH95lMfvLQQhkcHlCl8I=";
|
|
};
|
|
|
|
# catgirl's configure script uses pkg-config --variable exec_prefix openssl
|
|
# to discover the install location of the openssl(1) utility. exec_prefix
|
|
# is the "out" output of libressl in our case (where the libraries are
|
|
# installed), so we need to fix this up.
|
|
postConfigure = ''
|
|
substituteInPlace config.mk --replace \
|
|
"$($PKG_CONFIG --variable exec_prefix openssl)" \
|
|
"${lib.getBin libressl}"
|
|
'';
|
|
|
|
nativeBuildInputs = [ ctags pkg-config ];
|
|
buildInputs = [ libressl ncurses ];
|
|
strictDeps = true;
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = with lib; {
|
|
homepage = "https://git.causal.agency/catgirl/about/";
|
|
license = licenses.gpl3Plus;
|
|
description = "TLS-only terminal IRC client";
|
|
platforms = platforms.unix;
|
|
mainProgram = "catgirl";
|
|
maintainers = with maintainers; [ xfnw ];
|
|
};
|
|
}
|