mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-12 00:33:10 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
58 lines
1.2 KiB
Nix
58 lines
1.2 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, pkg-config
|
|
, lv2
|
|
, libGLU
|
|
, libGL
|
|
, gtk2
|
|
, cairo
|
|
, pango
|
|
, fftwFloat
|
|
, libjack2
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "meters.lv2";
|
|
version = "0.9.20";
|
|
robtkVersion = "0.7.5";
|
|
|
|
nativeBuildInputs = [ pkg-config ];
|
|
buildInputs = [ lv2 libGLU libGL gtk2 cairo pango fftwFloat libjack2 ];
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "x42";
|
|
repo = "meters.lv2";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-eGXTbE83bJEDqTBltL6ZX9qa/OotCFmUxpE/aLqGELU=";
|
|
};
|
|
|
|
robtkSrc = fetchFromGitHub {
|
|
owner = "x42";
|
|
repo = "robtk";
|
|
rev = "v${robtkVersion}";
|
|
sha256 = "sha256-L1meipOco8esZl+Pgqgi/oYVbhimgh9n8p9Iqj3dZr0=";
|
|
};
|
|
|
|
postUnpack = ''
|
|
rm -rf $sourceRoot/robtk/
|
|
ln -s ${robtkSrc} $sourceRoot/robtk
|
|
'';
|
|
|
|
postPatch = ''
|
|
substituteInPlace Makefile --replace "-msse -msse2 -mfpmath=sse" ""
|
|
''; # remove x86-specific flags
|
|
|
|
meter_VERSION = version;
|
|
enableParallelBuilding = true;
|
|
makeFlags = [ "PREFIX=${placeholder "out"}" ];
|
|
|
|
meta = with lib; {
|
|
description = "Collection of audio level meters with GUI in LV2 plugin format";
|
|
mainProgram = "x42-meter";
|
|
homepage = "https://x42.github.io/meters.lv2/";
|
|
license = licenses.gpl2;
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|