mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-18 02:44:30 +00:00
50ba995a1c
Polaris is a self-hosted music streaming server, with a web and android frontend. The web frontend is included. https://github.com/agersant/polaris Polaris-web uses an odd versioning schema: 'build-X'. We reuse the upstream tags. Polaris CI releases automatically bundle the latest available version of polaris-web, however 'polaris' has seen no release since april 2021, while polaris-web has had 5 version bumps since. Currently we package the version of polaris-web bundled with polaris on github. Once the newer versions are tested we might upgrade.
57 lines
2.0 KiB
Nix
57 lines
2.0 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, rustPlatform
|
|
, polaris-web
|
|
}:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "polaris";
|
|
version = "0.13.5";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "agersant";
|
|
repo = "polaris";
|
|
rev = "${version}";
|
|
sha256 = "sp1KDTzKvcGtuqL37fFnVgcnkIsmj5ZQji72BeyiFQE=";
|
|
|
|
# The polaris version upstream in Cargo.lock is "0.0.0".
|
|
# We're unable to simply patch it in the patch phase due to
|
|
# rustPlatform.buildRustPackage fetching dependencies before applying patches.
|
|
# If we patch it after fetching dependencies we get an error when
|
|
# validating consistency between the final build and the prefetched deps.
|
|
postFetch = ''
|
|
# 'substituteInPlace' does not support multiline replacements?
|
|
sed -i $out/Cargo.lock -z \
|
|
-e 's/\[\[package\]\]\nname = "polaris"\nversion = "0.0.0"/[[package]]\nname = "polaris"\nversion = "'"${version}"'"/g'
|
|
'';
|
|
};
|
|
|
|
cargoSha256 = "sha256-0VHrlUoyYu+UTUQUioftBDlQJfLd/axz6bGJs+YXSmE=";
|
|
|
|
# Compile-time environment variables for where to find assets needed at runtime
|
|
POLARIS_WEB_DIR = "${polaris-web}/share/polaris-web";
|
|
POLARIS_SWAGGER_DIR = "${placeholder "out"}/share/polaris-swagger";
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/share
|
|
cp -a docs/swagger $out/share/polaris-swagger
|
|
'';
|
|
|
|
passthru.updateScript = ./update.sh;
|
|
|
|
meta = with lib; {
|
|
description = "Self-host your music collection, and access it from any computer and mobile device";
|
|
longDescription = ''
|
|
Polaris is a FOSS music streaming application, designed to let you enjoy your music collection
|
|
from any computer or mobile device. Polaris works by streaming your music directly from your
|
|
own computer, without uploading it to a third-party. There are no kind of premium version.
|
|
The only requirement is that your computer stays on while it streams your music!
|
|
'';
|
|
homepage = "https://github.com/agersant/polaris";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ pbsds ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|