mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-16 18:53:17 +00:00
f41a3e7d7d
* trying to build emscriptenPackages not all fail * reading the console.log it turns out python executable is not in place and that is why emconfigure didnt work * backup commit * much more targets are compiling now * added common revisioning * revision bump to 1.37.36 (not tested) * fixed xmllint * forcing unit testing, will implement the tests after i get home * json_c test working * added tests * tiny fixes * added documentation
56 lines
1.5 KiB
Nix
56 lines
1.5 KiB
Nix
{ emscriptenVersion, stdenv, llvm, fetchFromGitHub, cmake, python, gtest, ... }:
|
|
|
|
let
|
|
rev = emscriptenVersion;
|
|
gcc = if stdenv.cc.isGNU then stdenv.cc.cc else stdenv.cc.cc.gcc;
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
name = "emscripten-fastcomp-${rev}";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "kripken";
|
|
repo = "emscripten-fastcomp";
|
|
sha256 = "04j698gmp686b5lricjakm5hyh2z2kh28m1ffkghmkyz4zkzmx98";
|
|
inherit rev;
|
|
};
|
|
|
|
srcFL = fetchFromGitHub {
|
|
owner = "kripken";
|
|
repo = "emscripten-fastcomp-clang";
|
|
sha256 = "1ici51mmpgg80xk3y8f376nbbfak6rz27qdy98l8lxkrymklp5g5";
|
|
inherit rev;
|
|
};
|
|
|
|
nativeBuildInputs = [ cmake python gtest ];
|
|
preConfigure = ''
|
|
cp -Lr ${srcFL} tools/clang
|
|
chmod +w -R tools/clang
|
|
'';
|
|
cmakeFlags = [
|
|
"-DCMAKE_BUILD_TYPE=Release"
|
|
"-DLLVM_TARGETS_TO_BUILD='X86;JSBackend'"
|
|
"-DLLVM_INCLUDE_EXAMPLES=OFF"
|
|
"-DLLVM_INCLUDE_TESTS=ON"
|
|
#"-DLLVM_CONFIG=${llvm}/bin/llvm-config"
|
|
"-DLLVM_BUILD_TESTS=ON"
|
|
"-DCLANG_INCLUDE_TESTS=ON"
|
|
] ++ (stdenv.lib.optional stdenv.isLinux
|
|
# necessary for clang to find crtend.o
|
|
"-DGCC_INSTALL_PREFIX=${gcc}"
|
|
);
|
|
enableParallelBuilding = true;
|
|
|
|
passthru = {
|
|
isClang = true;
|
|
inherit gcc;
|
|
};
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://github.com/kripken/emscripten-fastcomp;
|
|
description = "Emscripten LLVM";
|
|
platforms = platforms.all;
|
|
maintainers = with maintainers; [ qknight matthewbauer ];
|
|
license = stdenv.lib.licenses.ncsa;
|
|
};
|
|
}
|