mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-17 02:14:08 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
62 lines
1.9 KiB
Nix
62 lines
1.9 KiB
Nix
{ lib, stdenvNoCC }:
|
|
/*
|
|
This is a wrapper around `substitute` in the stdenv.
|
|
|
|
Attribute arguments:
|
|
- `name` (optional): The name of the resulting derivation
|
|
- `src`: The path to the file to substitute
|
|
- `substitutions`: The list of substitution arguments to pass
|
|
See https://nixos.org/manual/nixpkgs/stable/#fun-substitute
|
|
- `replacements`: Deprecated version of `substitutions`
|
|
that doesn't support spaces in arguments.
|
|
|
|
Example:
|
|
|
|
```nix
|
|
{ substitute }:
|
|
substitute {
|
|
src = ./greeting.txt;
|
|
substitutions = [
|
|
"--replace"
|
|
"world"
|
|
"paul"
|
|
];
|
|
}
|
|
```
|
|
|
|
See ../../test/substitute for tests
|
|
*/
|
|
args:
|
|
|
|
let
|
|
name = if args ? name then args.name else baseNameOf (toString args.src);
|
|
deprecationReplacement = lib.pipe args.replacements [
|
|
lib.toList
|
|
(map (lib.splitString " "))
|
|
lib.concatLists
|
|
(lib.concatMapStringsSep " " lib.strings.escapeNixString)
|
|
];
|
|
optionalDeprecationWarning =
|
|
# substitutions is only available starting 24.05.
|
|
# TODO: Remove support for replacements sometime after the next release
|
|
lib.warnIf (args ? replacements && lib.oldestSupportedReleaseIsAtLeast 2405) ''
|
|
pkgs.substitute: For "${name}", `replacements` is used, which is deprecated since it doesn't support arguments with spaces. Use `substitutions` instead:
|
|
substitutions = [ ${deprecationReplacement} ];'';
|
|
in
|
|
optionalDeprecationWarning stdenvNoCC.mkDerivation (
|
|
{
|
|
inherit name;
|
|
builder = ./substitute.sh;
|
|
inherit (args) src;
|
|
preferLocalBuild = true;
|
|
allowSubstitutes = false;
|
|
}
|
|
// args
|
|
// lib.optionalAttrs (args ? substitutions) {
|
|
substitutions =
|
|
assert lib.assertMsg (lib.isList args.substitutions)
|
|
''pkgs.substitute: For "${name}", `substitutions` is passed, which is expected to be a list, but it's a ${builtins.typeOf args.substitutions} instead.'';
|
|
lib.escapeShellArgs args.substitutions;
|
|
}
|
|
)
|