mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-31 18:15:54 +00:00
d6628cffd1
Unfortunately, there’s no release announcement for this release. From the [NEWS][1]. > Version 0.21.1 - October 2022 > > * Runtime behaviour: > - On AIX, locale names with a script or with an uppercase language are now > supported. > For example, sr_Cyrl_RS.UTF-8 is treated like sr_RS.UTF-8@cyrillic, and > EN_US.UTF-8 is treated like en_US.UTF-8. > > * The base Unicode standard is now updated to 14.0.0. > > * Portability: > - Building on macOS 11/arm64 is now supported. > - Building on Linux/powerpc64le with glibc ≥ 2.35 is now supported. The vendored gnulib was also updated, which indirectly fixes a build failure with clang 16. The version in 0.20 fails to build because it attempts to assign an incompatible function pointer that should have but does not have `__attribute__((noreturn))`. On clang 16, this is an error by default. [1]: https://git.savannah.gnu.org/gitweb/?p=gettext.git;a=blob_plain;f=NEWS;hb=8b38ee827251cadbb90cb6cb576ae98702566288
105 lines
3.9 KiB
Nix
105 lines
3.9 KiB
Nix
{ stdenv, lib, fetchurl, fetchpatch, libiconv, xz, bash
|
|
, gnulib
|
|
}:
|
|
|
|
# Note: this package is used for bootstrapping fetchurl, and thus
|
|
# cannot use fetchpatch! All mutable patches (generated by GitHub or
|
|
# cgit) that are needed here should be included directly in Nixpkgs as
|
|
# files.
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "gettext";
|
|
version = "0.21.1";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://gnu/gettext/${pname}-${version}.tar.gz";
|
|
sha256 = "sha256-6MNlDh2M7odcTzVWQjgsHfgwWL1aEe6FVcDPJ21kbUU=";
|
|
};
|
|
patches = [
|
|
./absolute-paths.diff
|
|
] ++ lib.optional stdenv.hostPlatform.isWindows (fetchpatch {
|
|
url = "https://aur.archlinux.org/cgit/aur.git/plain/gettext_formatstring-ruby.patch?h=mingw-w64-gettext&id=e8b577ee3d399518d005e33613f23363a7df07ee";
|
|
name = "gettext_formatstring-ruby.patch";
|
|
sha256 = "sha256-6SxZObOMkQDxuKJuJY+mQ/VuJJxSeGbf97J8ZZddCV0=";
|
|
});
|
|
|
|
outputs = [ "out" "man" "doc" "info" ];
|
|
|
|
hardeningDisable = [ "format" ];
|
|
|
|
LDFLAGS = lib.optionalString stdenv.isSunOS "-lm -lmd -lmp -luutil -lnvpair -lnsl -lidmap -lavl -lsec";
|
|
|
|
configureFlags = [
|
|
"--disable-csharp" "--with-xz"
|
|
] ++ lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
|
|
# On cross building, gettext supposes that the wchar.h from libc
|
|
# does not fulfill gettext needs, so it tries to work with its
|
|
# own wchar.h file, which does not cope well with the system's
|
|
# wchar.h and stddef.h (gcc-4.3 - glibc-2.9)
|
|
"gl_cv_func_wcwidth_works=yes"
|
|
];
|
|
|
|
postPatch = ''
|
|
substituteAllInPlace gettext-runtime/src/gettext.sh.in
|
|
substituteInPlace gettext-tools/projects/KDE/trigger --replace "/bin/pwd" pwd
|
|
substituteInPlace gettext-tools/projects/GNOME/trigger --replace "/bin/pwd" pwd
|
|
substituteInPlace gettext-tools/src/project-id --replace "/bin/pwd" pwd
|
|
'' + lib.optionalString stdenv.hostPlatform.isCygwin ''
|
|
sed -i -e "s/\(cldr_plurals_LDADD = \)/\\1..\/gnulib-lib\/libxml_rpl.la /" gettext-tools/src/Makefile.in
|
|
sed -i -e "s/\(libgettextsrc_la_LDFLAGS = \)/\\1..\/gnulib-lib\/libxml_rpl.la /" gettext-tools/src/Makefile.in
|
|
'';
|
|
|
|
strictDeps = true;
|
|
nativeBuildInputs = [
|
|
xz
|
|
xz.bin
|
|
];
|
|
buildInputs = [ bash ]
|
|
# HACK, see #10874 (and 14664)
|
|
++ lib.optionals (!stdenv.isLinux && !stdenv.hostPlatform.isCygwin) [ libiconv ];
|
|
|
|
setupHooks = [
|
|
../../../build-support/setup-hooks/role.bash
|
|
./gettext-setup-hook.sh
|
|
];
|
|
env = {
|
|
gettextNeedsLdflags = stdenv.hostPlatform.libc != "glibc" && !stdenv.hostPlatform.isMusl;
|
|
};
|
|
|
|
enableParallelBuilding = true;
|
|
enableParallelChecking = false; # fails sometimes
|
|
|
|
meta = with lib; {
|
|
description = "Well integrated set of translation tools and documentation";
|
|
|
|
longDescription = ''
|
|
Usually, programs are written and documented in English, and use
|
|
English at execution time for interacting with users. Using a common
|
|
language is quite handy for communication between developers,
|
|
maintainers and users from all countries. On the other hand, most
|
|
people are less comfortable with English than with their own native
|
|
language, and would rather be using their mother tongue for day to
|
|
day's work, as far as possible. Many would simply love seeing their
|
|
computer screen showing a lot less of English, and far more of their
|
|
own language.
|
|
|
|
GNU `gettext' is an important step for the GNU Translation Project, as
|
|
it is an asset on which we may build many other steps. This package
|
|
offers to programmers, translators, and even users, a well integrated
|
|
set of tools and documentation. Specifically, the GNU `gettext'
|
|
utilities are a set of tools that provides a framework to help other
|
|
GNU packages produce multi-lingual messages.
|
|
'';
|
|
|
|
homepage = "https://www.gnu.org/software/gettext/";
|
|
|
|
maintainers = with maintainers; [ zimbatm vrthra ];
|
|
license = licenses.gpl2Plus;
|
|
platforms = platforms.all;
|
|
};
|
|
}
|
|
|
|
// lib.optionalAttrs stdenv.isDarwin {
|
|
makeFlags = [ "CFLAGS=-D_FORTIFY_SOURCE=0" ];
|
|
}
|