mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-06 04:53:27 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
44 lines
1.4 KiB
Nix
44 lines
1.4 KiB
Nix
{ stdenv, lib, fetchurl, pam ? null, libX11, libXext, libXinerama
|
|
, libXdmcp, libXt, autoreconfHook }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "xlockmore";
|
|
version = "5.80";
|
|
|
|
src = fetchurl {
|
|
url = "http://sillycycle.com/xlock/xlockmore-${version}.tar.xz";
|
|
sha256 = "sha256-UC12U2jTbYFOy3d/1DnHWXkLPdNNXuNfdIB/cbqkdiE=";
|
|
curlOpts = "--user-agent 'Mozilla/5.0'";
|
|
};
|
|
|
|
# Optionally, it can use GTK.
|
|
buildInputs = [ pam libX11 libXext.dev libXinerama libXdmcp libXt ];
|
|
nativeBuildInputs = [ autoreconfHook ];
|
|
|
|
# Don't try to install `xlock' setuid. Password authentication works
|
|
# fine via PAM without super user privileges.
|
|
configureFlags =
|
|
[ "--disable-setuid"
|
|
] ++ (lib.optional (pam != null) "--enable-pam");
|
|
|
|
postPatch =
|
|
let makePath = p: lib.concatMapStringsSep " " (x: x + "/" + p) buildInputs;
|
|
inputs = "${makePath "lib"} ${makePath "include"}";
|
|
in ''
|
|
sed -i 's,\(for ac_dir in\),\1 ${inputs},' configure.ac
|
|
sed -i 's,/usr/,/no-such-dir/,g' configure.ac
|
|
configureFlags+=" --enable-appdefaultdir=$out/share/X11/app-defaults"
|
|
'';
|
|
|
|
hardeningDisable = [ "format" ]; # no build output otherwise
|
|
|
|
meta = with lib; {
|
|
description = "Screen locker for the X Window System";
|
|
homepage = "http://sillycycle.com/xlockmore.html";
|
|
license = licenses.gpl2Only;
|
|
maintainers = with maintainers; [ pSub ];
|
|
platforms = platforms.linux;
|
|
mainProgram = "xlock";
|
|
};
|
|
}
|