mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-21 04:13:12 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
60 lines
1.3 KiB
Nix
60 lines
1.3 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, cmake
|
|
, fmt
|
|
, catch2_3
|
|
, staticBuild ? stdenv.hostPlatform.isStatic
|
|
|
|
# tests
|
|
, bear
|
|
, tiledb
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "spdlog";
|
|
version = "1.14.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "gabime";
|
|
repo = "spdlog";
|
|
rev = "v${version}";
|
|
hash = "sha256-F7khXbMilbh5b+eKnzcB0fPPWQqUHqAYPWJb83OnUKQ=";
|
|
};
|
|
|
|
nativeBuildInputs = [ cmake ];
|
|
# Required to build tests, even if they aren't executed
|
|
buildInputs = [ catch2_3 ];
|
|
propagatedBuildInputs = [ fmt ];
|
|
|
|
cmakeFlags = [
|
|
"-DSPDLOG_BUILD_SHARED=${if staticBuild then "OFF" else "ON"}"
|
|
"-DSPDLOG_BUILD_STATIC=${if staticBuild then "ON" else "OFF"}"
|
|
"-DSPDLOG_BUILD_EXAMPLE=OFF"
|
|
"-DSPDLOG_BUILD_BENCH=OFF"
|
|
"-DSPDLOG_BUILD_TESTS=ON"
|
|
"-DSPDLOG_FMT_EXTERNAL=ON"
|
|
];
|
|
|
|
outputs = [ "out" "doc" "dev" ] ;
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/share/doc/spdlog
|
|
cp -rv ../example $out/share/doc/spdlog
|
|
'';
|
|
|
|
doCheck = true;
|
|
|
|
passthru.tests = {
|
|
inherit bear tiledb;
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Very fast, header only, C++ logging library";
|
|
homepage = "https://github.com/gabime/spdlog";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ obadz ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|