mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-14 17:04:42 +00:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
97 lines
2.4 KiB
Nix
97 lines
2.4 KiB
Nix
{ stdenv
|
|
, lib
|
|
, fetchurl
|
|
, pkg-config
|
|
, python3
|
|
, freetype
|
|
, expat
|
|
, libxslt
|
|
, gperf
|
|
, dejavu_fonts
|
|
, autoreconfHook
|
|
, CoreFoundation
|
|
, testers
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "fontconfig";
|
|
version = "2.15.0";
|
|
|
|
outputs = [ "bin" "dev" "lib" "out" ]; # $out contains all the config
|
|
|
|
src = fetchurl {
|
|
url = with finalAttrs; "https://www.freedesktop.org/software/fontconfig/release/${pname}-${version}.tar.xz";
|
|
hash = "sha256-Y6BljQ4G4PqIYQZFK1jvBPIfWCAuoCqUw53g0zNdfA4=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
autoreconfHook
|
|
gperf
|
|
libxslt
|
|
pkg-config
|
|
python3
|
|
];
|
|
|
|
buildInputs = [
|
|
expat
|
|
] ++ lib.optional stdenv.hostPlatform.isDarwin CoreFoundation;
|
|
|
|
propagatedBuildInputs = [
|
|
freetype
|
|
];
|
|
|
|
postPatch = ''
|
|
# Requires networking.
|
|
sed -i '/check_PROGRAMS += test-crbug1004254/d' test/Makefile.am
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--sysconfdir=/etc"
|
|
"--with-arch=${stdenv.hostPlatform.parsed.cpu.name}"
|
|
"--with-cache-dir=/var/cache/fontconfig" # otherwise the fallback is in $out/
|
|
# just <1MB; this is what you get when loading config fails for some reason
|
|
"--with-default-fonts=${dejavu_fonts.minimal}"
|
|
] ++ lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
|
|
"--with-arch=${stdenv.hostPlatform.parsed.cpu.name}"
|
|
];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
doCheck = true;
|
|
|
|
installFlags = [
|
|
# Don't try to write to /var/cache/fontconfig at install time.
|
|
"fc_cachedir=$(TMPDIR)/dummy"
|
|
"RUN_FC_CACHE_TEST=false"
|
|
"sysconfdir=${placeholder "out"}/etc"
|
|
];
|
|
|
|
postInstall = ''
|
|
cd "$out/etc/fonts"
|
|
xsltproc --stringparam fontDirectories "${dejavu_fonts.minimal}" \
|
|
--stringparam includes /etc/fonts/conf.d \
|
|
--path $out/share/xml/fontconfig \
|
|
${./make-fonts-conf.xsl} $out/etc/fonts/fonts.conf \
|
|
> fonts.conf.tmp
|
|
mv fonts.conf.tmp $out/etc/fonts/fonts.conf
|
|
# We don't keep section 3 of the manpages, as they are quite large and
|
|
# probably not so useful.
|
|
rm -r $bin/share/man/man3
|
|
'';
|
|
|
|
passthru.tests = {
|
|
pkg-config = testers.hasPkgConfigModules {
|
|
package = finalAttrs.finalPackage;
|
|
};
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Library for font customization and configuration";
|
|
homepage = "http://fontconfig.org/";
|
|
license = licenses.bsd2; # custom but very bsd-like
|
|
platforms = platforms.all;
|
|
maintainers = with maintainers; teams.freedesktop.members ++ [ ];
|
|
pkgConfigModules = [ "fontconfig" ];
|
|
};
|
|
})
|