mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-08 14:03:29 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
64 lines
1.6 KiB
Nix
64 lines
1.6 KiB
Nix
{ lib, stdenv, fetchFromGitLab, gitUpdater, meson, mesonEmulatorHook, ninja, glib, check, python3, vala, gtk-doc, glibcLocales
|
|
, libxml2, libxslt, pkg-config, sqlite, docbook_xsl, docbook_xml_dtd_43, gobject-introspection }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "libaccounts-glib";
|
|
version = "1.27";
|
|
|
|
outputs = [ "out" "dev" "devdoc" "py" ];
|
|
|
|
src = fetchFromGitLab {
|
|
owner = "accounts-sso";
|
|
repo = "libaccounts-glib";
|
|
rev = "VERSION_${version}";
|
|
hash = "sha256-mLhcwp8rhCGSB1K6rTWT0tuiINzgwULwXINfCbgPKEg=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
check
|
|
docbook_xml_dtd_43
|
|
docbook_xsl
|
|
glibcLocales
|
|
gobject-introspection
|
|
gtk-doc
|
|
meson
|
|
ninja
|
|
pkg-config
|
|
vala
|
|
] ++ lib.optionals (!stdenv.buildPlatform.canExecute stdenv.hostPlatform) [
|
|
mesonEmulatorHook
|
|
];
|
|
|
|
buildInputs = [
|
|
glib
|
|
libxml2
|
|
libxslt
|
|
python3.pkgs.pygobject3
|
|
sqlite
|
|
];
|
|
|
|
# TODO: send patch upstream to make running tests optional
|
|
postPatch = lib.optionalString (!stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
|
|
substituteInPlace meson.build \
|
|
--replace "subdir('tests')" ""
|
|
'';
|
|
|
|
LC_ALL = "en_US.UTF-8";
|
|
|
|
mesonFlags = [
|
|
"-Dinstall-py-overrides=true"
|
|
"-Dpy-overrides-dir=${placeholder "py"}/${python3.sitePackages}/gi/overrides"
|
|
];
|
|
|
|
passthru.updateScript = gitUpdater {
|
|
rev-prefix = "VERSION_";
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Library for managing accounts which can be used from GLib applications";
|
|
homepage = "https://gitlab.com/accounts-sso/libaccounts-glib";
|
|
platforms = platforms.linux;
|
|
license = licenses.lgpl21;
|
|
};
|
|
}
|